Thanks dude.

Was just what i was looking for.

Christian.


"Remco de Korte" <rem### [at] onwijscom> wrote in message
news:3F78127B.6CEA1907@onwijs.com...
> Christian Bryndum wrote:
> >
> > Thanks again to all of you. I really appreciate it. Ive been playing
around
> > with Warps vertex's and Frank's star code. And im getting closer.
> > What i was thinking of now, is to use Warps vertex's and then combine
them
> > with some sort of box or line? im looking for something similar to the
> > attached file.
> >
> > Thanks a mill again guys.
> >
> > Christian
> >
> >  [Image]
>
> Here are some suggestions:
>
> #1, the basic idea
> #2, an optical trick (relying on the orthographic camera)
> #3, more towards what you wish
> #4, some experimenting and it starts to look like it (without
> orthographics)
>
> You may have a closer look at some of the values, but this was fairly
> easy to find.
>
> Cheers!
>
>
> (Oops, just realized I can't attach the pov code as binary here, so I'll
> quote it:)
>
> #########################################################
> star1.pov:
> #########################################################
>
> camera {orthographic location <0,0,-100> look_at <0,0,0> angle 60 }
>   light_source { <-100,100,-50> rgb<1,1,1> }
>   light_source { <100,50,-50> rgb<.7,.7,.7>  shadowless}
>   light_source { <100,200,20> rgb<.4,.4,.4> shadowless}
>   light_source { <0,100,50> rgb<.1,.1,.1> shadowless}
>
> #declare tt=0;#while (tt<5)
>   #declare p1=vrotate(<0,20,0>,<0,0,tt*72>);
>   #declare p2=vrotate(<0,20,0>,<0,0,(tt+2)*72>);
>   sphere{p1,1 pigment{rgb<1,.8,.2>}}
>   cylinder{p1,p2,1 pigment{rgb<1,.8,.2>}}
> #declare tt=tt+1;#end
>
> #########################################################
> star2.pov
> #########################################################
>
> camera {orthographic location <0,0,-100> look_at <0,0,0> angle 60 }
>   light_source { <-100,100,-50> rgb<1,1,1> }
>   light_source { <100,50,-50> rgb<.7,.7,.7>  shadowless}
>   light_source { <100,200,20> rgb<.4,.4,.4> shadowless}
>   light_source { <0,100,50> rgb<.1,.1,.1> shadowless}
>
> #declare tt=0;#while (tt<5)
>   #declare p1=vrotate(<0,25,0>,<0,0,tt*72>);
>   #declare p2=vrotate(<0,25,0>,<0,0,(tt+2)*72>);
>   #declare p3=<(p1.x*2+p2.x)/3,(p1.y*2+p2.y)/3,-1>;
>   sphere{p1,1 pigment{rgb<1,.8,.2>}}
>   cylinder{p1,p3,1 pigment{rgb<1,.8,.2>}}
>   cylinder{p3,p2,1 pigment{rgb<1,.8,.2>}}
>
>   #declare p1=vrotate(<0,40,0>,<0,0,tt*72>);
>   #declare p2=vrotate(<0,40,0>,<0,0,(tt+2)*72>);
>   #declare p3=<(p1.x*2+p2.x)/3,(p1.y*2+p2.y)/3,-1>;
>   sphere{p1,1 pigment{rgb<1,.8,.2>}}
>   cylinder{p1,p3,1 pigment{rgb<1,.8,.2>}}
>   cylinder{p3,p2,1 pigment{rgb<1,.8,.2>}}
> #declare tt=tt+1;#end
>
> #########################################################
> star3.pov
> #########################################################
>
> camera {orthographic location <0,0,-100> look_at <0,0,0> angle 60 }
>   light_source { <-100,100,-50> rgb<1,1,1> }
>   light_source { <100,50,-50> rgb<.7,.7,.7>  shadowless}
>   light_source { <100,200,20> rgb<.4,.4,.4> shadowless}
>   light_source { <0,100,50> rgb<.1,.1,.1> shadowless}
>
> #declare tt=0;#while (tt<5)
>
>   difference{
>     union{
>       box{<-40,-2,0><40,2,1> pigment{rgb<.6,.7,.8>}}
>       cylinder{<-40,-2,0><40,-2,0>,.5 pigment{rgb<1,.8,.2>}}
>       cylinder{<-40,2,0><40,2,0>,.5 pigment{rgb<1,.8,.2>}}
>       translate y*10
>     }
>     union{
>       box{<0,3,-1><50,-25,2> rotate z*18 translate <10,0,0>
> pigment{rgb<1,0,0>}}
>       box{<-50,3,-1><0,-25,2> rotate z*-18 translate <-10,0,0>
> pigment{rgb<1,0,0>}}
>     }
>     rotate z*tt*72
>   }
>
> #declare tt=tt+1;#end
>
> #########################################################
> star4.pov
> #########################################################
>
> camera {location <0,0,-100> look_at <0,0,0> angle 60 }
>   light_source { <-100,100,-50> rgb<1,1,1> }
>   light_source { <100,50,-50> rgb<.7,.7,.7>  shadowless}
>   light_source { <100,200,20> rgb<.4,.4,.4> shadowless}
>   light_source { <0,100,50> rgb<.1,.1,.1> shadowless}
>
> #declare tt=0;#while (tt<5)
>
>   difference{
>     union{
>       box{<-40,-2,0><40,2,1> pigment{rgb<.6,.7,.8>}}
>       cylinder{<-40,-2,0><5.85,-2,0>,.5 pigment{rgb<1,.8,.2>}}
>       cylinder{<10,-2,0><40,-2,0>,.5 pigment{rgb<1,.8,.2>}}
>       cylinder{<-40,2,0><4.75,2,0>,.5 pigment{rgb<1,.8,.2>}}
>       cylinder{<9,2,0><40,2,0>,.5 pigment{rgb<1,.8,.2>}}
>       translate y*10
>     }
>     union{
>       box{<0,3,-1><50,-25,2> rotate z*18 translate <10,0,0>
> pigment{rgb<1,0,0>}}
>       box{<-50,3,-1><0,-25,2> rotate z*-18 translate <-10,0,0>
> pigment{rgb<1,0,0>}}
>     }
>     rotate z*tt*72
>   }
>
> #declare tt=tt+1;#end

Post a reply to this message