Well, then "projected_through" is the way to go.
Here's a small sample scene. The Glass-Sphere's
shadow is red, because it originates from the
red lightsource projecting through the sphere. I've
also made it less powerful. Note that the red light
will only cast through the sphere, so thats only where
the original shadow would be. Hence placing the
two lightsources at the same position: the first
casts a shadow, the second fills the shaded area
with light. It might be good to make the second
light a little weaker, so that at least a little shadow
is left.


global_settings{
 assumed_gamma 1
 photons{spacing .05 autostop .1}
 }
camera{location <0,2,-4> look_at <0,.5,0>}
#declare Glass_Ball=sphere{y,1
 pigment{rgbt <1,1,1,.99>}
 finish{
  specular .9 roughness .01
  reflection{0,.9 fresnel}
  }
 interior{ior 1.56}
 photons{refraction on target}
 }

object{Glass_Ball}
light_source{<20,30,40> rgb 1 photons{refraction on}}
light_source{<20,30,40> rgb x*.5 photons{refraction off reflection off}
projected_through{Glass_Ball}}
plane{y,0 pigment{rgb .5}}


Regards,
Tim

-- 
Tim Nikias v2.0
Homepage: http://www.digitaltwilight.de/no_lights
Email: no_lights (@) digitaltwilight.de


> Hey thanks for quick answer! I made some birthday card and have letters
for
> name made in glass: you know how beatifull is dispersion in "diamond" like
> objects made with photons and POV-Ray. So mine idea is to make "dimond
> like" letters. Those letters will produce dispersion of white like : and
> everything is good except shadow from letters (you are right in this piece
> - I dont need realism/shadow for this part!
> Now you are have clearer picture of mine problem!
> Thanks one more time.
> Pepi
>


---
Outgoing mail is certified Virus Free.
Checked by AVG anti-virus system (http://www.grisoft.com).
Version: 6.0.518 / Virus Database: 316 - Release Date: 11.09.2003

Post a reply to this message