"DL" <dav### [at] hotmailcom> wrote in message
news:3e55d883@news.povray.org...
> How can I create ripple effect like when a helicopter is flying above a
> water surface?  I could use the "ripples" pattern but I don't want the
whole
> water surface to become rippled.  I want the ripples to gradually fade
away
> from the center.  I also don't want the ripples to originate exactly from
> the center because that is not realistic when a helicopter is flying
> overhead.  The ripples should around the perimeter of the helicopter.

Okay. This is what I'd do...

global_settings {
    number_of_waves 5
}

#declare S=0.09; // ripples scaling
#declare N0=normal {ripples 0}
#declare N1=normal {ripples 0.9
    phase -clock*3 // spread outward when animated
  turbulence 0.3 scale S}
#declare N2=normal {ripples 0.3
    phase -clock*3 // spread outward when animated
  turbulence 0.9 scale S/1.5}

plane {y,0
 pigment {rgb 1}
normal {
    spherical
        normal_map {
[0 N0] // this is the outermost edge
[1/6 N2] // less wavy water
[1/2 N1] // more wavy water
[2/3 N2] // less wavy water
[1 N0] // this is the center
        }
scale 2 // adjust overall size here
}
 finish {specular .5}
}

You could also make a pigment to match this by following the same principal,
if you needed frothing water for example.
Maybe I'm giving too simple an answer but then that's about all I'm good
for.
--
Farewell,
Bob

Post a reply to this message