"kosinj2" <kos### [at] felcvutcz> wrote in message
news:web.3e456aba1f9e1881cc31a200@news.povray.org...
> I want a transparent prism wit high ior
> and I got something just mirror instead with:
> texture { T_Glass3 }
> interior {   I_Glass1
>                 ior 2.42
>              dispersion 1.035
>              dispersion_samples 50
>              fade_distance 30
>              fade_power 1
>              }
> or very dark looking thing with the same code like above, just without the
> fade
> stuff....
>
> What I am doing wrong?

Nothing. It is solid for CSG purposes, media too. As Warp had said, objects
are only surfaces. They start off solid though, in the sense that they
interact as if they had substance throughout their interiors. And until the
keyword hollow is applied media or fog will not fill them.

The darkness you see is only from the light fading into it. What you seem to
have perceived as being mirror-like too is probably just the transparency
showing the background (and surroundings) through it. However, in trying
your script out I needed to use a pigment checker pattern surrounding the
scene to see that it was indeed refracting; and a sphere I differenced away
from it made the prism look peculiar too in the area the sphere took away
but it's just a case of refraction making the object complex in appearance.
If you try the following you will see:


#include "glass.inc"

global_settings {
/* important for multiple reflections and/or transparent surfaces */
 max_trace_level 10
}

difference {
mesh {
        triangle {<0,0,0>, <10,0,0>,<0,0,10>}
        triangle {<0,30,0><10,30,0><0,30,10>}
        triangle {<0,0,0><10,0,0><10,30,0>}
        triangle {<0,0,0>,<0,30,0>,<10,30,0>}
        triangle {<0,0,0>,<0,0,10>,<0,30,10>}
        triangle {<0,0,0>,<0,30,0>,<0,30,10>}
        triangle {<10,0,0>,<0,0,10>,<0,30,10>}
        triangle {<10,0,0>,<10,30,0>,<0,30,10>}
inside_vector <5, 5, 5>
}
sphere {10,10}
texture { T_Glass3 }
interior {   I_Glass1
                ior 2.42
             dispersion 1.035
             dispersion_samples 50
             fade_distance 30
             fade_power 1//1001
             media {
              method 2
              scattering {1,.1}
             }
      }
 rotate -45*y
hollow // only here for media to show up
}

light_source {
  <-20, 40, -20>,1
}
camera {
  location  <0, 0, -50>
  look_at   <0, 0,  0>
  right     x*image_width/image_height
}
sky_sphere {
  pigment {
    checker color rgb 1 color rgb 0
 scale .25 }
}

Post a reply to this message