"Neil Conway" <nei### [at] yahoocom> wrote in message
news:web.3e3faf53e0395af21c4fca030@news.povray.org...
>
> Anyway: here's the question (at last!).  The media-emission process looks
> ideal except for the fact that the docs say it doesn't actually light up
> objects in the view, but rather just emits light which is viewable by the
> camera.  So, is it possible to patch povray to make it treat the emission
> from the media as a "real" light source?  Would this patch be a major job?
>

As Warp said, this is already possible (with limitations).

Here is a small sample scene (comment out "media on" in the global block to see
the difference) - note the lack of light sources and ambient_light 0.

#version 3.5;

global_settings {
  assumed_gamma 1.0
  ambient_light 0
  radiosity {
    media on
  }
}

camera {
  location  <0.0, 0, -4.99>
  look_at   <0.0, 0.0,  0.0>
}

sphere{
  0,1 pigment{rgbf 1}
  interior{
    media{
      emission 1
      density{
        agate density_map{
          [0.5 rgb 0]
          [1 rgb <20,1,1>]
        }
      }
      density{
        spherical
      }
    }
  }
  hollow
}

sphere {0.0, 5 pigment{rgb 1} hollow}

#declare N = 0;
#while(N <= 180)
  cylinder{y*-4,y*4 0.25 translate x*-1.5 rotate y*N pigment{rgb 1}}
  #declare N = N+45;
#end

Post a reply to this message