|
|
> also how easy is it to use transparency maps in pov? - is there a freeware
> garphics editor that works with layers and alpha channels?
>
> cheers
> jim
>
for transparency, fishnet stockings, lace or whatever I do suggest the use
of pigment_pattern like:
// the tranparency map, should be a grayscale image
#declare LacePat = pigment {image_map{png "LatticeTrans" interpolate 2} }
// the texture map
#declare LaceMap = pigment {image_map{jpg "LatticeTX" interpolate 2} }
// for the *invisible* parts
#local LaceTrans = texture{
pigment{LaceMap transmit 1 filter 0}
finish {diffuse .6 specular 0} //specular, reflection set to 0.0 !!!
}
// for the *visible* parts
#local LaceText = texture{
pigment{LaceMap}
finish {diffuse .6 specular .5 roughness 0.05}//you can also use
reflection
normal {pigment_pattern{LaceMap} 0.03 } // any normal statement here
}
// this is the final texture for the mesh and
// the name should match to the name given
// by the converter you use.
#declare T_Lace = texture {
pigment_pattern{LacePat}
texture_map {
[0.0 LaceTrans ]
[1.0 LaceText ]
}
}
there are 3 advatages compared to the (older) way by using images with
alpha channel:
1) easier to handle (you do not nead Photoshop or something like this)
2) there is no need to have the image and transparency map at the same size.
3.and most important I think) you can also apply specular highlights and
even reflections to the texture. This is not possible with alpha channels
'cause highlight and reflection is also applied to the *invisble* parts of
the texture.
If I would not be the lazy guy that I am, I had already written that short
tutorial - as promised already. BTW in the same way I have created the
cloth mesh for the Marshall speaker and I do also use this technique for
the XFrog plants.
hope this helps
-Ive
Post a reply to this message
|
|