"Sir Charles W. Shults III" <aic### [at] cflrrcom> wrote in message
news:3d311b6b$1@news.povray.org...
>     Can you put a second object exactly inside the first, but make it
> "no_shadow" and get what you want?  Then your fill light might be made to
fill
> the shadow area.  Not certain if this will work, but just a thought.

Would seem a plausible solution to me, yes. Using no_image on the duplicate
object with it having a shadow while the visible object has no_shadow. Or
I'm lost as to what the idea is ;-)

If specular highlights are involved then this might be another matter. No
wait, nevermind. no_shadow doesn't seem to affect that. Had to check.

I was thinking light_group could be the answer but a quick attempt to get
all the pieces together can be tricky. Just now, I managed a highlightless
and shadowless cone atop a sphere with highlighting and shadow, both lit by
a pair of spotlights but only one to each. Then I would need to consider the
floor plane, the dimmer spotlight shining into the shadowed area there.

Something's probably possible but I didn't get far enough to say the
original question could be done like that. In the following pov script I
also tried nesting the floor plane into the other groups but I'm not certain
you could ever get exactly the right setup to cover all the variables. Maybe
Chip had the right idea to begin with, without all the rest of this. I
needed the practice anyway.

// Shadow(less)/highlight(less)/spotlight light_groups example, for P-R v3.5

camera {
  location <-4, 4, -4>
  look_at y
  angle 60
}

union {

// visible sphere with shadow from previous lightgroup
light_group {
light_source { <10,20,-20>, <1,1,0>
        spotlight
        point_at y
        radius 1
        falloff 6 // each of these...
   // shadowless // comment out have highlighting
}
sphere { 0,1 }
 global_lights off
}

// cone without a shadow (shadowless light fouls this up*)
light_group {
light_source { <10,20,-20>, <1,0,1>/2
        spotlight
        point_at y
        radius 1
        falloff 3 // ...are not the same...
   // shadowless // comment out to have highlighting (*read above)
}
    cone { <0,1,0>, 1, <0,3,0>, 0 no_shadow}
 global_lights off
}
 pigment { color rgb <1,1,1> }
        finish {
                specular 0.9
                roughness 0.03
                ambient 0.2
                diffuse 0.7
    }
} // union

// floor, and shadow-making sphere (unseen besides)
light_group {
light_source { <10,20,-20>, <1,1,1>
        spotlight
        point_at y
        radius 1
        falloff 9 // ...just to be different
}
plane { y,-1
    pigment { checker color rgb <1,1,0>, color rgb <0,1,1> scale 0.5}
    finish { ambient 0 diffuse 1 }
}
sphere { 0,1
 pigment { color rgb <1,1,1> }
        no_image
        }
 global_lights on
}

Post a reply to this message