"Rune" <run### [at] mobilixnetdk> ha scritto nel messaggio
news:3c97b9c3@news.povray.org...
> "Christoph Hormann" wrote:
> > There is no complete shadow in your scene and with a
> > light source of color rgb 3 you should expect it being bright.
>
> You seem to assume I'm talking about that cloud scene? I'm not. This is my
> test scene:
>
> // global_settings{assumed_gamma 1}
> light_source {<1,2,-2>*100, rgb 1}
> sphere {3*z, 1 pigment {rgb 1}}

The default finishes (esp. ambient is way too high) do not match well with
assumed_gamma 1.
This worked for me:

global_settings {
    ambient_light 0
    assumed_gamma 1
}

#declare White_Texture =
texture {
    pigment {
        rgb 1}
    finish {
        ambient 0
        diffuse 0.75
        specular 0.65
        roughness 0.008
        reflection {0.03,1 falloff 5}
    }
    normal {
        bumps 0.05 scale 1}
}

sphere {
    3*y+5*z,3
    texture {
        White_Texture scale 0.08}
}

plane {y,0
    pigment {rgb 0}
    finish {ambient 0
        diffuse 0.8  specular 0.5 roughness 0.01 reflection 0.2
    }
}

light_source {
    <0,140,0>
    rgb 1
    area_light 30*x,30*z,5,5 adaptive 0 jitter circular orient
    fade_power 2
    fade_distance 100
}

light_source {
    <-30,80,-99>
    rgb 1
    area_light 10*x,10*y,5,5 adaptive 0 jitter circular orient
    fade_power 2
    fade_distance 120
}

light_source {
    <0,50,99>
    rgb 0.8
    area_light 10*x,10*y,5,5 adaptive 0 jitter circular orient
    fade_power 2
    fade_distance 100
}

#version 3.1;
camera {
    location <0,25,-40>
    right image_width/image_height*x
    look_at 5*y
    angle 20
    rotate 5*y
}

Post a reply to this message