"Rune" <run### [at] mobilixnetdk> wrote in message
news:3c928f52$1@news.povray.org...
> I've settled for a more rocky look for the desert, but I'd be very
> interested in the sky in that image of yours! :)
>
> Rune


Here you go, any question just ask.

// Start 'The Calling' Sky Code.

sky_sphere {
  pigment {
    rgb <0.8,0.82,0.86>*1.1
  }
}


fog {
  fog_type 2
  distance 3400
  fog_offset 0
  fog_alt 200
  color rgbf <0.8,0.8,0.75,0>*1
}

box {
  <-30000,700,-60000>
  <30000,900,60000>
  material {
    texture {
      pigment {rgbt 1}

    }
    interior {
      media {
        scattering {5, <0.0001,0.0001,0.0001> extinction 1 eccentricity
0.005}
        method 3
        intervals 2
        aa_level 4
        jitter 0.1
        density {
          bozo
          color_map{
           [0.0 rgb 0]
           [0.56 rgb 0]
           [0.56 rgb 1]
           [1.0 rgb <1,1,1> ]
          }
          scale <500,200,500>
          octaves 6
          lambda 2
          omega 0.65
          turbulence .75
          scale <2.5,2,2.5>
          translate <0,800,0>
        }
        density {
          planar
          color_map {
            [0 rgb 0]
            [0.1 rgb 0]
            [0.1 rgb 0.9]
            [1 rgb 0.9]
          }
          scale <20,20,20>*5
          turbulence 0.15
          translate <0,800,0>
        }
      }
    }
  }
  hollow
  scale 0.8
  rotate <0,456,0>
  translate <5000,300,4000>
}

Post a reply to this message