"Lutz Kretzschmar" <lut### [at] stmuccom> wrote in message
news:klbv0u0n3euu22dakt2a9eushjab7v6lqr@4ax.com...
> Hi all,
>
> I am trying to create a sort of a glow effect in a sphere and am not
> getting it quite right. I can still see a defined boundary around the
> media.
>
> What is the best way to create this effect?

Funnily enough, I sat myself down the other day to teach myself a bit of
media.  You need to use a spherical density map.  Try this (bit long-winded
because I tend to #declare everything):

#version 3.5;

global_settings {assumed_gamma 1.8}
background {rgb 0}

camera {
  location <0,0,-100>
  right x*image_width up y*image_height
  look_at 0
  angle 70
  perspective
}

#local media_colour1=<0.8,0.3,0.1>*0.1;

//    THE INTERESTING BIT
#local media_density1=density {
  spherical
  colour_map {
    [0.1 rgb 0]
    [0.3 rgb 1]
    [1.0 rgb 1]
  }
}

#local media_test1=media {
  method 3
  emission media_colour1
  density {media_density1}
}

#local txt_clear=texture {
  pigment {rgbf 1}
  finish {ambient 0 diffuse 1}
}

sphere {
  0 1
  scale <1,1,0.5>
  texture {txt_clear}
  interior {media {media_test1}}
  hollow on
  no_shadow
  scale 40
}


--
http://www.mp3.com/FeedingTheCats

Post a reply to this message