I have been trying to do scenes without specular highlighting for some time
now and take advantage of the fresnel type reflection.  I have been using a
white sphere with a high ambient value (say 100) with global ambient set to
1. All other textures have ambient set explicitly to 0.  This seems to work
as I want it to for shiny surfaces. I'm still working on a way to get a
blurred reflection.

-tgq

Try the following scene:

--start--
global_settings {
  assumed_gamma 1.0
  max_trace_level 25
  ambient_light 1
}

camera {
  up y
  right x*image_width/image_height
  location  <3,2,-3>
  look_at   <0,1,0>
}

#declare LB=sphere{0 .5 hollow pigment{rgb 1} finish{ambient 50}}

light_source{0
  rgb 1
  looks_like{LB}
  fade_power 2
  fade_distance 5
  translate <3,3,-3>
}

plane {y 0 pigment{checker rgb 1 rgb 0}}


#declare M1=
material{
  texture{
    pigment{red 1}
    finish{
      conserve_energy
      ambient 0
      diffuse 0
      reflection {
        0 1
        fresnel on
        metallic 1
      }
    }
  }
  interior{ior 25}
}

#declare M2=
material{
  texture{
    pigment{red 1}
    finish{
      conserve_energy
      ambient 0
      diffuse .25
      reflection {
        0 1
        fresnel on
        metallic 0
      }
    }
  }
  interior{ior 1.3}
}

sphere{<1,1,1> 1  material{M1}}
sphere{<-1,1,-1> 1  material{M2}}
--end--

Post a reply to this message