there is no third light_source an the shadow comes definately from the lamp 
left (or do i need glasses?).

here is the code:

--------------------------------------------


global_settings {
        ambient_light 4
}


//normale totale
#declare cam1 = camera {
        location<0,1,-1>
        //location<0,1,-3>
        look_at <0,1,0>
        }

camera{cam1}

//-----lamp right

#declare lamp=
union{
box {
        <-0.5,-0.5,-0.5>,<0.5,0.5,0.5>
        texture {
                pigment{
                        color White}
                }
        no_shadow
        finish{
                ambient 0.25
        }
        scale <0.2,0.2,0.05>
}
light_source {
        <0,0,0>
        color White
        area_light <2,0,0>,<0,0,2>,2,2  //doppelt so gr
        adaptive 1
        //jitter
        translate z*-0.1
}
}//union

object {lamp
        rotate y*45
        translate <0.9,1,1.8>
}

//-----lamp left

#declare neonroehre =
union {
cylinder {
        <0,0,0>,<1,0,0>,1
        scale <0.13,0.02,0.02>
        texture {
                pigment {
                        color rgb <0, 0.21, 1>}
        }
        finish {
                ambient 0
        }
        translate x*-0.28
}
cylinder {
        <0,0,0>,<1,0,0>,1
        scale <0.3,0.02,0.02>
        texture {
                pigment {color rgb <1, 1, 1>}
                finish {
                        ambient .8
                        diffuse .6
                        }
        }
        translate <-0.15,0,0>
}
        rotate y*-90
        //translate z*-.15

        rotate x*90
}//union

light_source {
        //<-0.9, 1.8, 1>
        <-0.98, 1, 1>
        color White
        looks_like { neonroehre }
}


//-----the box

plane {
        y,0
        texture {pigment {color <0.79,0.75,0.57>} }
}
plane {
        y,2
        texture {pigment {color <0.79,0.75,0.57>}}
}
plane {
        z,2
        texture {pigment {color <0.79,0.75,0.57>}}
}
plane {
        x,-1
        texture {pigment {color <1,0.55,0.55>}}
}
plane {
        x,1
        texture {pigment {color <0.3,0.66,1>}}
}

//-----table

#declare kl_tisch=
union{
box {   //platte
        <0,0,0>,<1,1,1>
        scale <1,0.03,0.4>
        translate y*0.37        //tischhoehe 0.4
}
box {   //linkes bein
        <0,0,0>,<1,1,1>
        scale <0.03,0.4,0.4>
}
box {   //rechtes bein
        <0,0,0>,<1,1,1>
        scale <0.03,0.4,0.4>
        translate x*0.97
}
        texture {
                T_Wood10
                scale 0.5
        }
}//Union


//-----mirror

#declare spiegel=
union{

#declare sp_br = 0.5;
#declare sp_ho = 0.3;
#declare sp_ti = 0.005; //spiegeltiefe
#declare ra_di = 0.01; //rahmendicke radius
#declare ra_pa = texture {T_Chrome_4A}

#declare rahm=
cylinder {
        <0,0,0>,<0,1,0>,1
        //texture {T_Wood10}
        texture {ra_pa}
        scale <ra_di,1,ra_di>
}
//spiegelflaeche
box {
        <0,0,0>,<1,1,1>
        scale <sp_br,sp_ho,sp_ti>
        texture {T_Chrome_5D}
        finish{
                ambient 0.01
                diffuse 0
                phong 0.9
                reflection 1
                brilliance 1
                specular 1
        }
}

box {
        <0,0,0>,<1,1,1>
        scale <0.5,0.3,0.0013>
        texture {T_Glass4}
        translate z*-0.005
        //translate z*-0.008
}
//rahmen

//links
object {rahm
        scale <1,sp_ho,1>
}
//unten
object {rahm
        scale <1,sp_br,1>
        rotate z*-90
}
//oben
object {rahm
        scale <1,sp_br,1>
        rotate z*-90
        translate <0,sp_ho,0>
}
//rechts
object {rahm
        scale <1,sp_ho,1>
        translate <sp_br,0,0>
}

sphere {
        <0,0,0>,ra_di
        texture {ra_pa}
}
sphere {
        <0,sp_ho,0>,ra_di
        texture {ra_pa}
}
sphere {
        <sp_br,0,0>,ra_di
        texture {ra_pa}
}
sphere {
        <sp_br,sp_ho,0>,ra_di
        texture {ra_pa}
}
}//union spiegel

object {spiegel
        rotate y*-45
        translate <-0.99,0.4+0.01,1.6> //wg steinen
}

object {kl_tisch
        translate <-0.5,0,1.5>
}

---------------------------------------------

Post a reply to this message