"Rob Brown-Bayliss" <on_### [at] clearnetnz> wrote in message
news:3bb97219@news.povray.org...
> Hi.  I am new to this whole 3d thing, and am ambitiously trying to create
> a jet engine of sorts.
>
> What I had planned to do was place a few different coloured spheres
> inside the rear end, with a light source behind them, make the spheres
> glass, add some bumps and hope that ir would look like some thing hot was
> happeneing inside.

You probably want to use media for something like this. At the moment you are
trying to reproduce an interior effect (hot glowing gasses), by reproducing the
surface appearence. A bit like painting sand white and expecting it to taste
like sugar.

>
> I got a pretty ugly looking yelow and orenge blob wit ha light glowing
> inside, but when I put bumps on one of the spheres the whole thing turned
> to a black orb.
>

Hmm, that sounds like a problem with max_trace_level (check the docs).

> Anyone able to point me towards a decent alterative?  I have looked at
> media, perhapse a working example here would be cool as well.
>

Media is definately the way to go. Try something like:

// 'orrible media demo
#include "colors.inc"

camera {
  location  <0.0, 0.5, -15.0>
  look_at   <0.0, 0.0,  0.0>
}


sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------



union{
  cylinder{0,y*5,1.01 pigment{White}}

  difference{
    sphere{0,1}
    plane{-y,0}
    hollow
    pigment{rgbf 1}
    interior{
      media{
        emission rgb 5
        absorption rgb 5
        density{spherical turbulence 0.25 color_map{[0 rgb 0][1/6 Red][2/6
Blue][3/6 Yellow]}}
        density{wrinkles scale 10}
      }
    }
    scale<1,4,1>
  }
  rotate z*90
}

Post a reply to this message