Do you want to earn easy money without risks and very fast?
  This is your lucky day! You can make any amount of money with this
sensational new method! No more hard work. No more risks spending your own
money. It's easy and fast!

  Just set the 'MoneyAmount' identifier to any number you want, and you will
earn that amount of money!

//------8<--------8<-----------8<----------8<-----------8<--------8<-----

#declare MoneyAmount=20;

#include "colors.inc"
#declare Coin=
  union
  { difference
    { cylinder
      { 0,y*.3,2
        pigment { Copper }
        normal
        { radial 1 slope_map { [0 <0,1>][.5 <1,0>][1 <0,-1>] }
          frequency 120
        }
        finish { specular .5 metallic reflection .1 }
      }
      cylinder { -y*.01,y*.05,1.9 }
      cylinder { y*.31,y*.25,1.9 }
    }
    union
    { difference
      { cylinder { <0,.2,.8><0,.35,.8>,1 }
        cylinder { <0,.2,.8><0,.36,.8>,.6 }
        box { <.001,.2,-.2><1,.36,.8> }
      }
      difference
      { cylinder { <0,.2,-.8><0,.35,-.8>,1 }
        cylinder { <0,.2,-.8><0,.36,-.8>,.6 }
        box { <0,.2,.2><-1,.36,-.8> }
      }
      scale <1,1,.8>
    }
    box { <-.08,.2,-1.7><.08,.35,1.7> translate -x*.25 }
    box { <-.08,.2,-1.7><.08,.35,1.7> translate x*.25 }
    pigment { Copper }
    normal { bumps .1 scale .1 }
    finish { specular .5 metallic reflection .1 }
    scale .5
  }

camera { location <0,1,-1>*(sqrt(MoneyAmount)*2+5) look_at 0 angle 35 }
light_source { <50,200,-100> 1 }
plane { y,0 pigment { granite scale 5 } }

#declare Loc=array[MoneyAmount]
#declare R=seed(0);
#declare Ind=0;
#while(Ind<MoneyAmount)
  #declare Dist=sqrt(Ind)*2;
  #declare Loc[Ind]=<rand(R)*Dist-Dist/2,0,rand(R)*Dist-Dist/2>;
  #declare Ind2=0;
  #while(Ind2<Ind)
    #declare cx=Loc[Ind2].x-Loc[Ind].x;
    #declare cz=Loc[Ind2].z-Loc[Ind].z;
    #if(cx*cx+cz*cz<4 & Loc[Ind2].y=Loc[Ind].y)
      #declare Loc[Ind]=Loc[Ind]+y*.15;
      #declare Ind2=0;
    #else
      #declare Ind2=Ind2+1;
    #end
  #end
  object { Coin rotate y*rand(R)*360 translate Loc[Ind] }
  #declare Ind=Ind+1;
#end

//------8<--------8<-----------8<----------8<-----------8<--------8<-----

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message