"light emitting foggy things"? Not in POV-Ray sir, sorry to say.
However, if you meant simulated (isn't everything?) then the answer
might be multiple medias or rather multiple torii with a 'media' in each
along with a 'light_source'. Some such thing. Check out the demo scenes
under Scenes\Interior\Media for some examples. Mapping to a torus try
using the 'ripples' pattern in the 'density' statement using a
'density_map' or 'color_map'.
I don't think radiosity is going to work on the media so no glow via
that.

//following is the Hollow3.pov modified for this purpose:

global_settings {
number_of_waves 0  //removes the multiple wave pattern interferences
 }

#include "colors.inc"

camera {
  location <-1.5, 30, -150>
  look_at <0, 25, 35>
  angle 35
}

background { color rgb<0.2, 0.4, 0.8> }

light_source { <0, 0, 0> color rgb <1.5,1.25,.25> } //light at center of
torus (no good really)

plane { y, -2
   pigment { rgb <.7,.8,.9> }
   normal {granite .025 scale .025}
   finish {ambient .3 diffuse 1 reflection 0.15}
   hollow
}

//sphere { 0, 1
//cylinder {-y,y,1
torus {.667,.333
  pigment {
    //checker YellowGreen, rgbt<1, 1, 1, 0.7>
    rgbf 1
    scale <0.4, 0.5, 0.2>
    rotate <90, 0, -90>
  }
  finish {
    brilliance 8
    phong 1
    phong_size 100
  }
  interior {
    media {
      emission 0.05
      intervals 10
      samples 1, 1
      confidence 0.999
      variance 1/100
      density {
        ripples //waves //spherical
        ramp_wave
        frequency 1//3
        turbulence 0//1
        color_map {
          [0.0 color rgb <0, 0, 0>]
          [0.1 color rgb <1, 0, 0>]
          [1.0 color rgb <1, 1, 0>]
        }  scale .5 translate .25 //reposition to fit torus
      }
    }
  }
  scale 25 rotate -45*x
  translate 25*y 
  hollow
} 

// END


Bob


Matt wrote:
> 
> I want to create a glowing multilayered torus of plasma to play with.
> Can anyone suggest how  to get started with such light emitting foggy
> things please?
> 
> Many thanks in advance
> 
> Matt Moose.
> N Wales

-- 
 omniVERSE: beyond the universe
  http://members.aol.com/inversez/homepage.htm
 mailto://inversez@aol.com?Subject=PoV-News

Post a reply to this message