Thorsten Froehlich wrote:
> 
> Hello, would anybody here in the newusers group be so kind help him?
> 
>     Thanks in advance, Thorsten

You bet !

> > But now onto my problem...
> 
> > Anyway, the field has two texture layers on it. The first one (and hence
> > the "bottom" layer) is a bright sandy agate that works marvellously to
> > produce sand. The second is a y gradient composed of bands of dark
> > filtering brown and complete transparency, which is intended to darken
> > the parts of the height field that are touching the edge of the water
> > (for a "wet sand" look).
> >
> > The problem is that when I apply the two textures to the side of a
> > simple box (for testing), they combine as expected, but when applied to
> > the height field the second texture doesn't show up.
> >
> > Here's the height field code, in case anyone can glean anything helpful
> > from it:

  Try the following changes and see if they help. What I did was reduce the
filter amount in the second layer a bit plus added a finish statement to
each texture. This allows you to control how "bright" the underlying layer
is to a certain extent along with the filtering amount controlling how
much of the lower layer is allowed to show through. It looked pretty good
with the HF I applied it to using the settings I choose below but you
need to tailor them to your own scene. I also added a little turbulence
to the gradient pattern so it looked a little more natural rather than
perfectly banded gradients.

 height_field
  {
  tga "dirt.tga"
  smooth translate <-.5,0,-.5>
  texture
   {
   pigment
    {
    agate
    color_map
     {
     [0.2 color rgb <1,.9,.8>]
     [0.4 color rgb <.8,.7,.6>]
     [0.7 color rgb <1,.8,.6>]
     [1 color rgb <.8,.6,.4>]
     }
    }
   finish
    {
      ambient .3 diffuse .45 // change these to make this layer lighter/darker
     }
    }
  texture
   {
   pigment
    {
    gradient y
     turbulence <.1,.3,.1>
    color_map
     {
     [0.4375 rgbf < 1, 1, 1,.51>]
     [0.4375 rgbf <.5,.5,.5,.51>]
     [0.6000 rgbf <.5,.5,.5,.51>]
     [0.6000 rgbf < 1, 1, 1,.51>]
     }
    scale 4
    translate <0,-2,0>
    }
     finish
      {
      ambient .13 diffuse .2 // change these to make this layer lighter/darker
     }
   }
  scale <150,4,150> 
   translate <-75,-2,-10>
 }


-- 
Ken Tyler
  
mailto://tylereng@pacbell.net
http://home.pacbell.net/tylereng/links.htm

Post a reply to this message