Hello Simon
Try this :

#macro MakeIcicle(n,rad,qrad,rs)
// n : elements
// rad : radius
// qrad : decrease radius
// rs : seed
#declare rd=seed(rs);
blob{
threshold 0.6
#local i=0;
#local ys=0;
#while (i<n)
        #local rx=(0.5-rand(rd))*rad*1.5;
        #local rz=(0.5-rand(rd))*rad*1.5;
        sphere{0,rad,1 scale
<2,1+qrad*(i+1),2>*<1+rand(rd)*0.5,1,1+rand(rd)*0.5> translate <rx,ys,rz>}
        sphere{0,rad*1.3,1 translate <rx*2,ys-rand(rd),0> rotate
y*360*rand(rd)}
        sphere{0,rad*1.3,1 translate <rx*2,ys-rand(rd),0> rotate
y*360*rand(rd)}
        sphere{0,rad*1.3,1 translate <rx*2,ys-rand(rd),0> rotate
y*360*rand(rd)}
        #local rad=rad*qrad;
        #local ys=ys-qrad*1.5;
#local i=i+1;
#end
}

#end

// creates a row of 20 icicles
#declare i=0;
#declare rd=seed(456);
union{
#while (i<20)
#declare rs=i;
#declare sc=0.5+2*rand(rd);
        object{MakeIcicle(20,1,0.9,rs) scale sc translate x*i*8}
        #local i=i+1;
#end
pigment{rgb<1,0.3,0.1>}

}

Gilles Tran


Simon de Vet wrote:

> Any ideas on how to make those rust-icicles you see on the wrek of the
> Titanic, and other ship wrecks?
>
> Some ideas:
>
> Blobs: Probably most realistic. However, would have to do some coding to
> get them randomized, and I am not a coding kind of person...
>
> Heightfields: Good to get more complex shapes, and cover large areas at
> one time. However, very hard to look anywhere near realistic...
>
> Media: Some kind of media, in cylinders or cones? I know nothing about
> the intracies of the field, so I'll leave this one out, for now...
>
> Any other ideas?
>
> Simon
> http://home.istar.ca/~sdevet

Post a reply to this message