On Fri, 3 Jan 2003 20:02:03 -0500
"Dennis Miller" <dhm### [at] attbicom> wrote:

> Thank for your reply. Where is the message in which Jamie describes
> this technique> I must have missed it.

 The basic trick consists on using a surrounding sphere with a
multilayer texture like this one (more or less, I'm still
experimenting with it):

--
// "back-lighting" layer
texture{
 pigment{
  image_map{
   jpeg "test.jpg" 
   map_type 1 
   interpolate 2
  }
 }
 finish{
  diffuse 0 
  ambient light_ambient
 }
}
// 254 layers to fake the HDR behavoir
texture{
 pigment{
  image_map{
   gif "test.gif"  // grayscale version of the original map 
   map_type 1 
   #while (il<254)
//    transmit 255-il max_intensity/(pow(il+1,2))
    filter 255-il max_intensity/(pow(il+1,2))
    #local il=il+1;
   #end
  }
 } 
 finish{
  diffuse 0 
  ambient 0
 }
}
// final layer to hide the grayscale maps 
texture{
 pigment{
  image_map{
   jpeg "test.jpg" 
   map_type 1 
   interpolate 2 
//   filter all .5
   filter all .9
  }
 } 
 finish{
  diffuse 1 
  ambient 1
 }
}
--

  The problem is that each map needs diferent settings that must be
found by trial and error. The advantage is that it can work with any 
image where the brightness levels are somewhat proportional to real
luminance. Aditionally, you need a program to convert the image to a
grayscale one with ordered palette (255=white, 0=black). I've done it
with The Gimp, simply saving the grayscale version as gif.

-- 
Jaime Vives Piqueres
		
La Persistencia de la Ignorancia
http://www.ignorancia.org

Post a reply to this message