Try this:
you need to scale the color map and make the first and last entries in the
color map 0



// Persistence Of Vision raytracer version 3.1 sample scene by Mike
Hazelgrove
// based on Hollow3 by Dieter Bayer.
//
// This scene shows a flame.
// by Mike Hazelgrove based on Hollow3
//

#include "colors.inc"

camera {
  location <-1.5, 30, -50>
  look_at <0, 25, 35>
  angle 35
}

background { color rgb<0.3,0.3,0> }

light_source { <100, 100, -200> color White }


sphere { 0, 1
  pigment {rgbf<1,1,1,1>}
  interior {
    media {
      emission 0.5
      intervals 20
      samples 1, 10
      confidence 0.9999
      variance 1/1000
      density {
       spherical
       scallop_wave
        turbulence 0.5
        color_map {
          [0.0 color rgb <0, 0, 0>] //You need this
          [0.25 color rgb <1, 0., 0>]
          [0.5 color rgb <1, 1, 0>]
          [0.75 color rgb <1, 0, 0>]
          [1.0 color rgb <0, 0, 0>]// you need this
        }
        scale 0.5 //you need this
      }
    }
  }
  scale 3
  scale <1,3,1>
  translate 25*y
  hollow
}



Dan Connelly <djc### [at] flashnet> wrote in article
<35A495A2.A7BC0409@flash.net>...
> Scott Middleton wrote:
> > 
> > This does make a great deal of sense.  Could you possibly supply an
> > example to get me started?  Thanks for the help!
> > 
> 
> 
> There is an example file in the standard 3.1 release called
> "hollow3.pov" (scenes/interior/media/) with an example of
> a media-generated flame.
> 
> Frankly, I'm still trying to figure it out myself, as I have
> been unable to transfer it into my own object and get it 
> to visibly render.... still, it's there.
> 
> Dan
> -- 
> http://www.flash.net/~djconnel/
>

Post a reply to this message