(using Windows 7 64-bit)

I haven't used a light_group in a long time, so I can't remember exactly what
its behavior was in v3.62, but I don't think it's working correctly in the beta.
I've included a test scene below.

Although the light_group's light does not appear on objects outside the group
(which is correct), it's still casting shadows from those objects, onto the
object in the light_group. Is that proper behavior? I don't recall a similar
problem in v3.62 (although I could be wrong.) The included documentation doesn't
mention shadow behavior (except as relates to scattering media.)

Also, the light's looks_like object (yellow sphere) is showing lighting effects
from the extra 'global light', even with 'global_lights off' in the light_group
(although there's no shadow from that sphere, as far as I can tell.) I don't
know if that is correct behavior or not.

--------
#version 3.71;

global_settings{assumed_gamma 1.0 max_trace_level 5}

camera {
  perspective
  location  <0, 0, -3.5>
  look_at   <0, 0,  0>
  right     x*image_width/image_height
  angle 35
}

background {rgb .2}

// the extra 'global light'-- up and to the left
light_source {
  0*x
  color rgb <1,1,1>
  translate <-30, 30, -10>
             }


light_group{
light_source {
  0*x
  color rgb 80000*<1,.5,.5>
  fade_power 1.5
  fade_distance .001
  looks_like{
     sphere{0,.03 texture{pigment{rgb <1,.8,0>}finish{ambient 0 diffuse .9}}}
            }
  translate <.09, .2, -.06>
             }
plane{y,-.61
    texture{
         pigment{
              cells
              scale .5
              color_map{
                   [0 rgb .5]
                   [1 rgb 1]
                       }
                }
         finish{
              ambient 0
              diffuse .4
               }
           }
     }
  // global_lights on
           }


// tall thin box
#declare TALL_BOX =
box{<-.02,-1,-.02>, <.02,1,.02>
    texture{
        pigment{rgb <.4,1,.4>}
        finish{ambient 0 diffuse .9}
           }
        rotate 30*y
   }

object{TALL_BOX}

object{TALL_BOX
rotate 80*x
translate <-.3,-.3,.3>
      }

Post a reply to this message