// Persistence of Vision Ray Tracer Scene Description File
// File: dif_phot.pov
// Vers: 3.5
// Desc: diffuse photon casting
// Date: 21.02.03 (dd.mm.yy)
// Auth: Tim Nikias Wenclawiak

//Description:
// A macro to show how diffuse objects might still reflect photons

//Homepage:
// www.digitaltwilight.de/no_lights
//Email:
// Tim.Nikias@gmx.de

global_settings{
 assumed_gamma 1
 photons{spacing .01 autostop 0}
 }

camera{location <0,2,-5> look_at <0,2,0>}
light_source{
 <-4,3,4> rgb .25
 photons{reflection off refraction off}
 }

light_source{
 <3,7,-2> rgb .6
 spotlight point_at <0,1,3> radius 12 falloff 15
 photons{reflection on refraction off}
 }

box{<-8,0,-8><8,8,8> inverse pigment{rgb 1}}
plane{x,-5 pigment{rgb x}}
plane{-x,-5 pigment{rgb y}}

#macro Diffuse_Photons(_Object,_Transform,_Photon_Mat,_Diffuse_Mat)
 object{
  _Object
  material{_Photon_Mat}
  transform{_Transform}
  photons{target reflection on refraction on}
  no_image
  }
 object{
  _Object
  material{_Diffuse_Mat}
  scale 1.0000001
  transform{_Transform}
  no_shadow
  }
#end

#declare Example_Obj=superellipsoid{<.1,.1>}
#declare Example_Transform=transform{rotate <14,62,36> translate <0,1,3>}

#declare Example_Photon_Material=
 material{
  texture{
   pigment{rgb 1}
   finish{reflection 1}
   }
  }
#declare Example_Diffuse_Material=
 material{
  texture{
   pigment{rgb 1}
   }
  }

Diffuse_Photons(Example_Obj,Example_Transform,Example_Photon_Material,Example_Diffuse_Material)