#include "colors.inc"

#declare Ambient_coef = 1;

#declare Use_Rad = false;
#declare Media_Neige = false;
#declare Fog_Neige = true;
#declare F_Blur = true;

#if (Use_Rad)
global_settings {
	ini_option "+QR"
	ini_option "Preview_Start_Size=16"
	ini_option "Preview_End_Size=8"

	radiosity{
		count 35             // CHANGE range from 20 to 150
		nearest_count 5      // CHANGE range from 3 to 10
		error_bound 2.25     // CHANGE - range from 1 to 3 - should correspond with Preview_End_Size
                         //   1 : preview_end_size = 4
                         //   3 : preview_end_size = 8
                         //   use preview_start_size = 16
                         // you can go lower than 1, but then you probably will want to set
                         // preview_end_size to 2, which is really slow
		recursion_limit 3    // CHANGE

		low_error_factor .5  // leave this
		gray_threshold 0.0   // leave this
		minimum_reuse 0.015  // leave this
		brightness 1         // leave this

		max_sample 1         // CHANGE - this should be the same as the brightest object
		adc_bailout 0.01/1   // CHANGE - use adc_bailout = 0.01 / brightest_ambient_object
  }
}
#end



light_source {
    <150,150,15> color rgb<1, 1, 1>/Ambient_coef
}


#if (Fog_Neige)
fog {
	fog_type 1
	distance 20
	color rgbft <.9,.9,.9,.2,.2>
}
#end

#if (Media_Neige)
box { <-6, -.1, -4>, <6, 10, 10>
	pigment { color rgbt <1,1,1,1> }
	interior {
		media {
			emission 4
			method 2
			intervals 10
			samples 1,1
			confidence .9
			variance 1/255
			density {
				leopard
				scale .4
				turbulence .3 omega 6 lambda .3
				color_map {
					[0.0	color rgb <0,0,0>]
					[0.95	color rgb <0,0,0>]
					[0.95	color rgb <.90,.98,.97>]
					[1.0	color rgb <.90,.98,.97>]
				}
			}
			rotate z*20
			rotate y*20
		}
	}
	hollow
}
#end


camera {
    location <0,2,-6>
    sky <0,1,0>
	right <1.5,0,0>
    look_at <1,1,0>
	angle 40
	rotate y*20
#if (F_Blur)
	blur_samples 40
	aperture .3
	focal_point <1,1,0>
#end
}


#declare T_Neige = texture {
	pigment { color rgb <.90, .98, .97> }
	normal { granite .2 scale .3 }
	finish { ambient 0.3/Ambient_coef specular .7 }
}


/* checkered floor */
box { <-10, -1, -10>, <10, 0, 6>
    pigment { checker color rgb 1 color rgb 0} finish { specular .2 }
	scale 2
}

isosurface {
	function{ y - abs(noise3d(x,y,z))*0.2 - abs(noise3d(x*10,y*10,z*10))*0.05 }
	bounded_by{ box {<-20, -.2, -20>, <20, 1, 12>} }
	eval
	threshold 0
	max_gradient 2
	method 2
	translate -.1*y
	texture { T_Neige }
}


/* sphere */
sphere { <0, 1, 0>, 1
	pigment { color rgb <0,.1,.8> }
	finish { ambient .2/Ambient_coef specular .5 }
}

isosurface {
	function{ x*x +y*y +z*z - abs(noise3d(x*10,y*10,z*10))*0.1*max(y-.2, 0) - 1}
	bounded_by{ box {<-1.2, .5, -1.2 >, <1.2, 1.2, 1.2 >} }
	eval
	threshold 0
	max_gradient 3.7
	method 2
	scale <.97, 1, .97>
	translate y*1
	texture { T_Neige }
}

/* box */
box { <-1,0,-1>, <1,2,1>
	pigment { color rgb <.8,.1,0>}
	finish { ambient .2/Ambient_coef specular .5 }
	rotate y*60
	translate <7, 0, 4>
}

isosurface {
	function{ max(max(abs(x), abs(y)), abs(z))-1 - abs(noise3d(x*10,y*10,z*10))*(1-sqrt(abs(y-1)))*0.1 }
	bounded_by{ box {<-1.2, .7, -1.2>, <1.3, 1.3, 1.3>} }
	eval
	threshold 0
	max_gradient 2.9
	method 2
	scale <.97, 1, .97>
	rotate y*60
	translate <7, 1, 4>
	texture { T_Neige }
}