#version 3.1;
#include "colors.inc"
global_settings {
  assumed_gamma 1.0
  max_trace_level 5
  adc_bailout 1/256
}

camera {
  location  <-3, 2, -12>
  fisheye
  angle 80
//  direction 3*z
  right     4/3*x
  look_at   <3, 0.5,  0.0>
}

background { colour rgb 0 }

light_source {
  <20,25,20>
  color rgb 1
  spotlight 
  point_at <-2,0,-10>
  radius 30
  falloff 40
  tightness 10

}

// ----------------------------------------
#declare S = 15;
plane { 
  y, 0 
  texture {
    pigment {
      bozo
      scale 1/S
      pigment_map {
        [0 
          checker 
          colour rgb <1,1,1>
          colour rgb <0,0,0>
          scale S 
        ]
        [1
          spiral1 4
          colour_map {
            [0 rgb 0]
            [1 rgb 1]
          }
          rotate 90*x
          scale S
        ]
      }
    }
    finish {
      ambient     0
      diffuse     0.7
      reflection  <0, 0, 0>
      phong       0.2
      phong_size  12
      specular    0.2
      roughness   0.08 
      crand       0.08
    }
    scale 1.5
  }  
}

#declare t1 =
texture {
  pigment { color rgbf <0.90, 0.90, 0.96, 0.55> }
  finish  {
    ambient 0.1
    diffuse 0.1
    reflection 0.1
    specular 0.8
    roughness 0.003
    phong 1
    phong_size 400
  }
}
#declare t2 =
texture {
  pigment { color rgbf <0.90, 0.90, 0.96, 0.55> }
  finish  {
    ambient 0.1
    diffuse 0.1
    reflection 1
    specular 0.8
    roughness 0.003
    phong 1
    phong_size 400
  }
}

// create a TrueType text shape
text {
  ttf 
  "bgothm.ttf", 
  "Tyst", 
  .5,<0,0,0>
  interior { ior 1.5 }
  texture {
    gradient y
    texture_map {
      [0 t2 ]
      [1/3 t2] 
      [2/3 t1 ]
      [1 t1 ]
    }
  }
  scale 8
  rotate y*30
  translate -x*7
}


sphere {
  <10, 10, 7>,  10
  pigment { colour rgb 1 }
  finish { ambient 0 reflection 1 diffuse 0}
  no_shadow
}