/*=-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-=*\

  Dave's Ring - Version 2
  
  This is my feeble attempt at recreating Henric Wann Jensen's
  cool"classic cardioid" caustic pattern
  (http://www.gk.dtu.du/home/hwj/
    and
   http://www.gk.dtu.dk/home/hwj/pictures/metalring.jpg)
  using Nathan Kopp's Photon Patch for POV-Ray
  (http://www.nathan.kopp/photons.htm).

  The problem with the original version was that the default
  setting for autostop was 0. Nathan kindly informed me that
  it should be set to 45. Viola! (Yeah, I know. I'm a lousy speller)

  By the way, I can see why HWJ used a wood-grain table setting.
  It really does bring out the caustic effect. I just grabbed one
  of the standard wood textures from the POV includes, but it
  gives the desired effect.

  23-Mar-99
  Dave Cook
  davepc2@netdave.com
  http://www.netdave.com/~davepc2

\*=-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=-=*/

#include "colors.inc"
#include "metals.inc"
#include "woods.inc"

#declare phd=2;
global_settings
{
  assumed_gamma 1.0 // this is a dark scene, make it brighter
  photons
  {
    gather 20,100
    radius 0.1*phd,2,0.1*phd
    autostop 45
  }
}

camera
{
  location <0, 10, -12.5>
  look_at <0, 0, 0>
  angle 75
}

light_source
{
  <500,350,-100>
  color rgb <1,1,1>
  photons
  {
    reflection on
    refraction on
  }
}

plane
{
  y, -1
  texture
  { T_Wood35 scale <50, 50, 50> }
  rotate <0, 45, 0>
}

#declare Ring =
lathe
{
  linear_spline
  5,
  <2, 1>, <2, -1>, <2.03, -1> <2.03, 1>, <2, 1>
}

object
{
  Ring
  scale < 3, 1.5, 3>
  texture { T_Copper_4E }
  photons
  {
    density 0.01*phd
    reflection on
    refraction off
  }
}