// A black_hole test on media (c)Juha Leppälä aka Jide 1999
// Feel free to tear it upside down. You can even just cut it and paste it to you're
// own work (but this isn't what a real POV-Spirit does)
// Have fun!


camera {
  location <10,6,-8>
  look_at <0,0,0>
}

sphere { 
  <0,0,0>,6 
  pigment { color rgbt 1 }
  interior { 
    media { //The lower media that looks like an explosion
      intervals 30 // Lower the intervals if you're unpatient like me :)
      samples 2,5
      emission 1
      confidence 0.99999
      variance 1/600
      density { //This density keeps the media inside the container
        spherical
        density_map {
          [0 color rgb 0]
          [0.3 color rgb 0.1]
          [1 color rgb 1]
        }
        scale 4.99
      }
      density { //If you remove (or comment out) the next two densitys, you'll end up with an explosion
        bozo
        density_map {
          [0 color rgb 0]
          [0.7 color rgb 0.01]
          [1 color rgb 1]
        }
        scale 0.5
        warp { turbulence 0.6 omega 0.8 }
        color_map {
          [0 color rgb <0.05,0,0>]
          [0.1 color rgb <0.5,0,0>]
          [1 color rgb <1,1,0>]
        }
      }
    }
      media {
      intervals 30
      samples 2,5
      emission 1
      confidence 0.99999
      variance 1/600
      density { //Again keeping the media in the container
        spherical
        density_map {
          [0 color rgb 0]
          [0.1 color rgb 0.2]
          [0.3 color rgb 0.5]
          [1 color rgb 1]
        }
        scale 5.8
      }
      density { //Here comes the "tentacles"
        bozo
        density_map {
          [0 color rgb 0]
          [0.99 color rgb 0.01]
          [0.995 color rgb 1]
        }
        scale 0.5
        warp { black_hole <0,0,0>,6 strength 3 } // I just love playing with black_holes
        warp { turbulence 0.2 omega 0.4 } //Add some randomness to the "tentacles", didn't want them to be straight
        color_map {
          [0 color rgb <0.001,0,0>]
          [0.98 color rgb <0.01,0,0>]
          [0.99 color rgb <0.5,0,0>]
          [1 color rgb <1,1,0>]
        }
      }
    }
  }        
  hollow
}