/*
  PoV v3.1 example scene file of poker playing chips
  Copyright Ken Tyler tylereng@pacbell.net  created 02-26-1999
  You are free to do with this as you wish.
  */ 


  // Pov is going to complain that the bounding for this object is unecessary.
  // If you leave it in it will render faster by about 20%-30%.
  // If you remove the bounding the render time will increase but Pov will
  // quit complaining about it. It's up to you but you have been warned.


  #declare F = 
  finish {
  ambient    0.150
  diffuse    0.350
  specular   1.000
  roughness  0.001
  brilliance 1.000
  reflection 0.025}

  #declare P1 = rgb<1,1,1>;
  #declare P2 = rgb<1,0,0>;
  #declare P3 = rgb<1,1,0>;
  #declare P4 = rgb<0,0,1>;


  // Make one 45 degree wedge

  #declare Section =
  intersection{
   cylinder{z*-0.1,z*0.1, 2}
    plane{y,0 rotate 67.5*-z} 
    plane{y,0 rotate 67.5* z}
  } // end intersection

  
  // The inside union rotates "Section" 8 times to produce a circle
  // with alternating colors. The difference is used to punch a hole
  // through the middle. The outside union attaches a one more cylinder
  // as a plug for the middle and is used with the declare for the object


  // red chips
  #declare Chip1 =
  union { 
    difference{ 
      union{
       object{Section rotate z*0.0 pigment{P1}finish{F}}
       object{Section rotate z*45  pigment{P2}finish{F}}
       object{Section rotate z*90  pigment{P1}finish{F}}
       object{Section rotate z*135 pigment{P2}finish{F}}
       object{Section rotate z*180 pigment{P1}finish{F}}
       object{Section rotate z*225 pigment{P2}finish{F}}
       object{Section rotate z*270 pigment{P1}finish{F}}
       object{Section rotate z*315 pigment{P2}finish{F}}
       } // end union
      cylinder{z*-0.11,z*0.11,1.7 pigment{P1}}finish{F}
     } //end difference
    cylinder{z*-0.08,z*0.08,1.8 pigment{P1}finish{F}}
   bounded_by{cylinder{z*-0.12,z*0.12,1.9}}
  } // end union


  // yellow chips
  #declare Chip2 =
  union{
    difference{
      union{
       object{Section rotate z*0.0 pigment{P1}finish{F}}
       object{Section rotate z*45  pigment{P3}finish{F}}
       object{Section rotate z*90  pigment{P1}finish{F}}
       object{Section rotate z*135 pigment{P3}finish{F}}
       object{Section rotate z*180 pigment{P1}finish{F}}
       object{Section rotate z*225 pigment{P3}finish{F}}
       object{Section rotate z*270 pigment{P1}finish{F}}
       object{Section rotate z*315 pigment{P3}finish{F}}
       } // end union
     cylinder{z*-0.11,z*0.11,1.7 pigment{P1}}finish{F}
     } //end difference
    cylinder{z*-.08,z*.08,1.8 pigment{P1}finish{F}}
   bounded_by{cylinder{z*-0.12,z*0.12,1.9}}
  } // end union


  // blue chips
  #declare Chip3 =
  union{
    difference{
      union{
       object{Section rotate z*0   pigment{P1}finish{F}}
       object{Section rotate z*45  pigment{P4}finish{F}}
       object{Section rotate z*90  pigment{P1}finish{F}}
       object{Section rotate z*135 pigment{P4}finish{F}}
       object{Section rotate z*180 pigment{P1}finish{F}}
       object{Section rotate z*225 pigment{P4}finish{F}}
       object{Section rotate z*270 pigment{P1}finish{F}}
       object{Section rotate z*315 pigment{P4}finish{F}}
       }  // end union
      cylinder{z*-0.11,z*0.11,1.7 pigment{P1}}finish{F}
     } //end difference
    cylinder{z*-0.08,z*0.08,1.8 pigment{P1}finish{F}}
   bounded_by{cylinder{z*-0.12,z*0.12,1.9}}
  } // end union


  // These are just a mechanism to rotate and stack the chips.

  // red chips
  #declare A =  0;
  #while  (A < 20)
  object{Chip1 rotate<90,-5*A,0>translate<-5,0.202*A,4>}
  #declare A = A + 1;
  #end

  // yellow chips
  #declare A =  0;
  #while  (A < 20)
  object{Chip2 rotate<90,5*A,0>translate<5,0.202*A,4>}
  #declare A = A + 1;
  #end


  // blue chips
  #declare A =  0;
  #while  (A < 20)
  object{Chip3 rotate<90,5*A,0>translate<0,0.202*A,2>}
  #declare A = A + 1;
  #end

  plane{y,-.02 pigment{rgb<0,.65,0>}finish{F}}

  light_source{<-30,10, -10>rgb 1}
  light_source{<-30, 2,-100>rgb 1}

  camera{location<0,8,-10>look_at y*2}


// End of File Ken Tyler 02-26-1999