// This is a little (cyclic) animation
// with a CD-like thing

// These numbers has something with wavelength to do,
// but I don't know exactly what.
#declare R = 5.0;
#declare G = 3.6;
#declare B = 2.8;

camera {
   location <1,3,-1>
   look_at 0
}

light_source {
   0
   color 1
   looks_like {
      sphere {
         0, 5
         pigment {color rgb 1}
         finish {ambient 1}
      }
   }
   translate 100*y
}

sphere { // sphere instead of sky_sphere which causes my pov to crash
   0, 1
   hollow
   pigment {spotted}
   finish {ambient 1 diffuse 0}
   scale 100
}

#declare CDX = // Reflective texture
texture {
   pigment {rgb <0,0,0>}
   normal {onion 0}
   finish {ambient 0 diffuse 0 reflection 7}
}

// the textures CD1 - CD6 controls the different phongs.

#declare CD1 =
texture {
   pigment {rgb <1,0,0>}
   normal {onion +R}
   finish {ambient 0 diffuse 0 phong 7 phong_size 80 metallic 1}
}

#declare CD2 =
texture {
   pigment {rgb <0,1,0>}
   normal {onion +G}
   finish {ambient 0 diffuse 0 phong 7 phong_size 80 metallic 1}
}

#declare CD3 =
texture {
   pigment {rgb <0,0,1>}
   normal {onion +B}
   finish {ambient 0 diffuse 0 phong 7 phong_size 80 metallic 1}
}

#declare CD4 =
texture {
   pigment {rgb <1,0,0>}
   normal {onion -R}
   finish {ambient 0 diffuse 0 phong 7 phong_size 80 metallic 1}
}

#declare CD5 =
texture {
   pigment {rgb <0,1,0>}
   normal {onion -G}
   finish {ambient 0 diffuse 0 phong 7 phong_size 80 metallic 1}
}

#declare CD6 =
texture {
   pigment {rgb <0,0,1>}
   normal {onion -B}
   finish {ambient 0 diffuse 0 phong 7 phong_size 80 metallic 1}
}

difference {
   cylinder {-0.01*y, +0.01*y, 1}
   cylinder {-y, +y, 0.1}
   texture {
      average
      texture_map {
         [1 CDX]
         [1 CD1]
         [1 CD2]
         [1 CD3]
         [1 CD4]
         [1 CD5]
         [1 CD6]
      }
      scale 2
   }
   rotate sin(clock*2*pi)*20*x
}