/* Test coin image */

#include "colors.inc"
#include "textures.inc"

camera {location -z*10 direction z*1.5 right x up y look_at 0}

light_source {<-5,10,-20>,color White}

// Ron Parker's three macros
// Find the advance width of character C in font F
#macro WidthWithSpacing( C, F )
  #local T=text {ttf F concat("|",C,"|") 1 0}
  #local W1=max_extent(T).x-min_extent(T).x;
  #local T=text {ttf F "||" 1 0}
  (W1-max_extent(T).x+min_extent(T).x)
#end
// Find the width of the glyph for character C in font F
#macro WidthNoSpacing( C, F )
  #local T=text {ttf F C 1 0}
  (max_extent(T).x-min_extent(T).x)
#end
// Find the kern for characters A and B from font F
#macro Kern( A, B, F )
  (WidthWithSpacing( concat(A, B), F)-WidthWithSpacing(A,F)
   -WidthWithSpacing(B,F))
#end

// other macros
#macro MaxHeight( A, F )
  #local T=text {ttf F A 1 0}
  max_extent(T).y
#end
#macro MaxDescent( A, F )
  #local T=text {ttf F A 1 0}
  -min_extent(T).y
#end

//  s1  - string
//  scl - scaling factor
//  r1  - inner radius of text
//  F   - font name
// NOTE: There is no error checking in this macro! k*scl<=2*r1 must be true
#macro AngleOf(s1,scl,r1,F)
  #local i=0;
  #local j=0;
  #while (i<strlen(s1))
    #local k=WidthWithSpacing(substr(s1,i+1,1),F);
    #if (i=0)
      #local j=asin(k*scl/r1/4);
    #end
    #if (i+1<strlen(s1))
      //#local k=k+WidthWithSpacing(substr(s1,i+2,1),F);
      #local k=WidthWithSpacing(substr(s1,i+1,2),F);
    #end
    #local j=j+asin(k*scl/r1/4);
    #local i=i+1;
  #end
  (j*360/pi)
#end

//  s1  - string
//  scl - scaling factor
//  F   - font name
#macro TotalChords(s1,scl,F)
  #local i=0;
  #local j=0;
  #while (i<strlen(s1))
    #local k=WidthWithSpacing(substr(s1,i+1,1),F);
    #if (i=0)
      #local j=k;
    #end
    #if (i+1<strlen(s1))
      //#local k=k+WidthWithSpacing(substr(s1,i+2,1),F);
      #local k=WidthWithSpacing(substr(s1,i+1,2),F);
    #end
    #local j=j+k;
    #local i=i+1;
  #end
  (j*scl/2)
#end
//  s1  - string
//  scl - scaling factor
//  a1  - desired total angle
//  prec- number of decimal places precision for radius
//  F   - font name
#macro RadiusOf(s1,scl,a1,prec,F)
  #local rmin=TotalChords(s1,scl,F)/(a1*pi/180);
  #local rmax=rmin*pi/2;
  #local prec=pow(10,(-prec));
  #while (rmax-rmin>prec)
    //#debug concat(str(rmin,0,8),"-",str(rmax,0,8),"\n")
    #local rg=(rmin+rmax)/2;
    #local ag=AngleOf(s1,scl,rg,F);
    //#debug concat("  ",str(ag,0,8),"\n")
    #if (ag>a1)
      #local rmin=rg;
    #else
      #if (ag<a1)
        #local rmax=rg;
      #else
        #local rmin=rg;
        #local rmax=rg;
      #end
    #end
  #end
  ((rmin+rmax)/2)
#end

//  s1  - string
//  scl - scaling factor
//  r1  - inner radius of text (may be negative for outer radius of bottom-out text)
//  radj- adjusts font "upward" (after scaling)
//  sadj- total angle of extra spacing between characters
//  F   - font name
// NOTE: There is no error checking in this macro! chord*scl<=2*r1 must be true
#macro CircleText(s1,scl,r1,radj,sadj,F)
  merge {
  #local i=0;
  #local j=0;
  #local r2=r1;
  #local rotvec=-z;
  #if (r1<0)
    #local r1=-r1;
    #local rotvec=z;
  #end
  #while (i<strlen(s1))
    #local k=WidthWithSpacing(substr(s1,i+1,1),F);
    #if (i=0)
      #local j=asin(k*scl/r1/4);
    #end
    text {ttf F substr(s1,i+1,1) 1 0 translate -k*x*0.5 scale <scl,scl,1> translate (r2+radj)*y rotate rotvec*(j*360/pi)}
    #if (i+1<strlen(s1))
      #local k=WidthWithSpacing(substr(s1,i+1,2),F);
      #local j=j+asin(k*scl/r1/4)+sadj*pi/360/(strlen(s1)-1);
    #end
    #local i=i+1;
  #end
  }
#end


merge {
    intersection {
      cylinder {-z*0.45,z*0.45,3}
      cylinder {-z*0.3,-z*1,2.85 inverse}
      cylinder {z*0.3,z*1,2.85 inverse}
      }
    merge {
      #declare s1=" EST OMNIA SUAE CULPA "
      #declare thefont="C:\Windows\Fonts\Times.ttf"
      #declare fontheight=0.3/MaxHeight(s1,thefont);
      #declare fonta=AngleOf(s1,fontheight,2.7,thefont);
      CircleText(s1,fontheight,-2.7,0,340-fonta,thefont)
      // -2.7: outer radius of text, bottom faces out
      // 0: No up/down adjustment of characters
      // 340-fonta: The string should fill 340°, so add remaining angle as spacing
      scale <1,1,0.3>
      translate -z*0.45
      rotate -z*0.5*340
      }
    //texture {pigment {color White} /*finish {ambient 1 diffuse 0}*/}
    texture {Gold_Texture}
    }