// This "test.pov" file demonstrates the BUG I have found
// in "triangle.c" from the povray 3.1g source code.

#include "colors.inc"
#include "woods.inc"
#include "glass.inc"
#include "golds.inc"

   #declare Triangle = 1;  // for the sphere buildt from smooth_triangles.
// #declare Triangle = 0;  // for the comparison with a normal sphere.
   #declare Scaled   = 1;  // The scaled "smooth_triangle sphere" is damaged.
// #declare Scaled   = 0;  // Unscaled sphere, no problems occur here.

#declare Nu  = 50;  // Number of trianges in
#declare Nv  = 50;  // each earth direction.
#declare Rad = 1;   // Radius of the sphere.

// This maps the spherical earth coordinates to 3D space:

#macro MapUV(U,V)
 <Rad*cos(pi*U),Rad*sin(pi*U)*cos(2*pi*V),Rad*sin(pi*U)*sin(2*pi*V)>
#end

// The normals for the unscaled sphere are really simple to calculate:

#macro Normal(P)
 #local Len=sqrt(P.x*P.x+P.y*P.y+P.z*P.z);
 <P.x/Len,P.y/Len,P.z/Len>
#end

// The complete object; many thanks to the new POVRAY language features,
// which make this possible (even if it takes longer than hard coded
// scene constructions in the C-language):

#macro MyObject()
 #local Iu=0;
 #while (Iu<Nu)
  #local Iv=0;
  #while (Iv<Nv)
   #local U1=Iu/Nu;
   #local V1=Iv/Nv;
   #local U2=(Iu+1)/Nu;
   #local V2=(Iv+1)/Nv;
   #local PU1V1=MapUV(U1,V1);
   #local PU2V1=MapUV(U2,V1);
   #local PU2V2=MapUV(U2,V2);
   #local PU1V2=MapUV(U1,V2);
   #local NU1V1=Normal(PU1V1);
   #local NU2V1=Normal(PU2V1);
   #local NU2V2=Normal(PU2V2);
   #local NU1V2=Normal(PU1V2);
   // Special net at the north pole (Iu=0):
   #if (Iu>0)
    smooth_triangle
    {
     PU1V1,NU1V1,
     PU2V1,NU2V1,
     PU1V2,NU1V2
    }
   #end
   // Special net at the south pole (Iu=Nu-1):
   #if (Iu<Nu-1)
    smooth_triangle
    {
     PU1V2,NU1V2,
     PU2V1,NU2V1,
     PU2V2,NU2V2
    } 
   #end 
   #local Iv=Iv+1;
  #end
  #local Iu=Iu+1;
 #end
#end

global_settings { assumed_gamma 2.2 }

camera
{
 location <-2,3,-3> 
 angle 40
 look_at <0,0,0>
}

light_source { <-10,10,-10> color White }
light_source { <10,10,-10>  color White }

background { color <0.0,0.5,0.5> }

// Building the test object:

#if (Triangle)
 union
 {
  MyObject()
  texture { T_Gold_1D }
  #if (Scaled)
   scale <1,0.3,1>
  #end
 }
#else
 sphere
 {
  <0,0,0>,1
  texture { T_Gold_1D }
  #if (Scaled)
   scale <1,0.3,1>
  #end
 }
#end