// Persistence of Vision Ray Tracer Scene Description File
// File: whiskey.pov
// Vers: 3.1
// Desc: CSG whiskey tumbler
// Date: 8/24/98
// Auth: ArfGrafix


// ==== Standard POV-Ray Includes ====
#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "glass.inc"
#include "metals.inc"
#include "skies.inc"


/*
// Set a color of the background (sky)
background { White }
*/




// An infinite planar surface
// plane {<A, B, C>, D } where: A*x + B*y + C*z = D
plane
{ y,0 pigment { brick pigment{LightGray},
  pigment{ Firebrick }

brick_size 3 mortar .5 } normal { bumps .25 scale .0425} hollow}

#declare camtop =
camera
{
  location  <0 ,4 ,-7>
  look_at   <0,3,0>

}
//********************************LIGHTS**********************************************

// create a regular point light source
light_source
{
  0*x // light's position (translated below)
  color red 1.0  green 1.0  blue 1.0  // light's color
  translate <-20, 60,-20>
}

// create a regular point light source
light_source
{
  0*x // light's position (translated below)
  color red 1.0  green 1.0  blue 1.0  // light's color
  translate <20, 60,-20>
}

light_source
{
 0*x // light's position (translated below)
  color red 1.0  green 1.0  blue 1.0  // light's color
  translate <0, 60,-20>
}
//************************************END LIGHTS*************************************

//******************************TEQUILA GLASS****************************************

#declare whiskey = //this is the liquid in the shot glass
          intersection {
       merge {
      sphere { <0,2,0>, 1.099 }
      cone { <0,2,0>, 1.099 <0,3.25,0>, 1.25 open}
             }
      plane { y, 2.5 pigment{ color rgbt <0.71, 0.65,  0.26, .5> }
               interior { ior 1.361 } }
                     }

 #declare straw = // the straw in the glass
   cylinder { <0,0,0>, <1.675,3.25,0>, .10 open
       scale <1,.93,1> translate y*1.2 }

#declare outercone = // the outer part and surface of the glass
    cone { <0,.1,0>, 1.2 <0,3,0>, 1.55 }

#declare innercone = // the hollow inner portion of the glass
    merge {
      sphere { <0,2,0>, 1.1 }
      cone { <0,2,0>, 1.1 <0,3,0>, 1.45 open}
          }

#declare glass = // the glass after the inner part( hollow ) is subtracted or differenced
    difference {
      object { outercone }
      object { innercone }
               }

#declare dimpler = //the sphere that creates the dimples in the base portion of the glass
      sphere { <-1.25,.7,0>,.35 scale <1,3,1> }

#declare thrill = // this is the routine that that creates the 
    union {      // dimples every 12 degrees about the base of the glass
  #declare c = 0;
    #while ( c < 360 )
       object { dimpler rotate y*c }
  #declare c = c + 30;
    #end
          }

#declare gwd = // this is the glass after it has been dimpled.
      difference {
        object { glass }
        object { thrill  }
                 }

//***********************END TEQUILA GLASS********************************************

//*********************PRESENTATION AREA**********************************************
camera { camtop }

      sky_sphere { S_Cloud4 }
      object { gwd texture { T_Old_Glass } }
      object { whiskey pigment{ color rgbf <0.71, 0.65,  0.26, .5> }
               interior { ior 1.361 } }
      object { straw pigment { gradient x
          color_map{ [0.5 color rgb<1,0,0>]
                     [0.5 color rgb<1,1,1>] }
          frequency 1 scale .05 } finish { phong 1 phong_size 125 } }
          /*
      object { dimpler pigment{ P_Silver1 } }
      */
//*******************END PRESENTATION AREA*********************************************