// Sample scene.
// 'yuqk triangles.pov +w100 +h100 +p +mv3.8 +kfi1 +kff6'
global_settings { assumed_gamma 1.0 }
#declare VarOrthoMult =
    3.0/max(image_width/image_height,image_height/image_width);
#declare Camera01z = camera {
    orthographic
    location <0,0,-2>
    direction z
    right VarOrthoMult*x*max(1,image_width/image_height)
    up VarOrthoMult*y*max(1,image_height/image_width)
}

//  default { finish { ambient 1.0 } }   //
    default { finish { emission 1.0 } }  //

#if (1)
    #declare N = <0,0,-1>;
#else
    #declare N = <0,0,+1>;
#end

#if (frame_number=1)  // ccw RED   (generated -z normal)
    triangle { <-1,-1,0>, <1,-1,0>, <0,1,0>
#end
#if (frame_number=2)  // cw  GREEN (generated +z normal)
    triangle { <-1,-1,0>, <0,1,0>,  <1,-1,0>
#end
#if (frame_number=3)  // ccw RED(-z) GREEN(+z)
    smooth_triangle { <-1,-1,0>,N, <1,-1,0>,N, <0,1,0>, N
#end
#if (frame_number=4)  // cw  RED(-z) GREEN(+z)
    smooth_triangle { <-1,-1,0>,N, <0,1,0>,N, <1,-1,0>,N
#end
#if (frame_number=5)  // ccw Negate 1 or 2 N and BLACK ?
    smooth_triangle { <-1,-1,0>,-N, <1,-1,0>,+N, <0,+1,0>,+N
#end
#if (frame_number=6)  // cw  Negate 1 or 2 N and BLACK ?
    smooth_triangle { <-1,-1,0>,+N, <0,+1,0>,-N, <1,-1,0>,+N
#end

    texture {
        pigment { rgb <1,0,0> }
      //finish { emission 1 }
    }
    interior_texture {
        pigment { rgb <0,1,0> }
      //finish { emission 1 }
    }
  //finish { emission 1 }  // Doesn't update interior_texture!
                           // Must push finish statements into
                           // both above.
  //finish { emission 1 }
  //interior_texture { finish { emission 1 } } // Turns white
}
camera { Camera01z }