// PoVRay 3.7 Scene File "tvTest.pov"
// author:  Dick Balaska
// date:    2017-04-28
//--------------------------------------------------------------------------
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }} 
//--------------------------------------------------------------------------
#include "colors.inc"

#declare IncludeWhiteInsert=1;
#declare ShowCutout=0;


#declare inches=1;

//--------------------------------------------------------------------------
// camera ------------------------------------------------------------------
#declare Camera_0 = camera {perspective angle 75               // look at whole TV
                            location  <14.0 , 12.0 ,-42.0>
                            right     x*image_width/image_height
                            look_at   <14.0 , 12.0 , 0.0>}
#declare Camera_1 = camera {perspective angle 75               // close up of lower left bezel
                            location  <2.0 , 2.5 ,-15.0>
                            right     x*image_width/image_height
                            look_at   <2.0 , 2.5 , 0.0>}
camera{Camera_1}
// sun ----------------------------------------------------------------------
light_source{< 3000,3000,-3000> color White}
// sky ----------------------------------------------------------------------
sky_sphere { pigment { gradient <0,1,0>
                       color_map { [0.00 rgb <0.6,0.7,1.0>]
                                   [0.35 rgb <0.1,0.0,0.8>]
                                   [0.65 rgb <0.1,0.0,0.8>]
                                   [1.00 rgb <0.6,0.7,1.0>] 
                                 } 
                       scale 2         
                     } // end of pigment
           } //end of skysphere
// ground -------------------------------------------------------------------
plane{ <0,1,0>, 0 
       texture{ pigment{ checker color rgb<1,1,1>*1.2 color rgb<0.25,0.15,0.1>*0}
                finish { phong 0.1}
              }
}
//---------------------------------------------------------------------------
//---------------------------- objects in scene ----------------------------
//---------------------------------------------------------------------------
#declare tvScreenWidth=27.5*inches;
#declare tvScreenHeight=22.5*inches;
#declare tvBorder=1.5*inches;
#declare tvWidth=tvScreenWidth+tvBorder;
#declare tvHeight=tvScreenHeight+tvBorder;

#local scRad=0.75*inches;
#local scBack=-6*inches;
#local scFront=15*inches;
#local bezel=1.5*inches;
#local tvDepth=10*inches;
#declare TV=
	union {
		difference {
			#if (!ShowCutout)
				merge {		// TV box
					box {
						<bezel, 0, 0> <tvWidth-bezel, tvHeight, tvDepth>
					}
					box {
						<0, bezel, 0> <tvWidth, tvHeight-bezel, tvDepth>
					}
					cylinder {<bezel, bezel, 0> <bezel,bezel, tvDepth> bezel }
					cylinder {<bezel, tvHeight-bezel, 0> <bezel,tvHeight-bezel, tvDepth> bezel }
					cylinder {<tvWidth-bezel, bezel, 0> <tvWidth-bezel,bezel, tvDepth> bezel }
					cylinder {<tvWidth-bezel, tvHeight-bezel, 0> <tvWidth-bezel,tvHeight-bezel, tvDepth> bezel }
					texture {	
						pigment {Red}
						finish {
							reflection 0.0001
						}
					}
				}
			#end
			merge {		// screen cutout
				box {
					<tvBorder, tvBorder+scRad, scBack-0.0001> <tvWidth-tvBorder, tvHeight-tvBorder-scRad, scFront>
				}
				box {
					<tvBorder+scRad, tvBorder, scBack> <tvWidth-tvBorder-scRad, tvHeight-tvBorder, scFront>
				}
				cylinder {<tvBorder+scRad, tvBorder+scRad, scBack-0.01> 
						  <tvBorder+scRad, tvBorder+scRad, scFront> scRad}
				cylinder {<tvBorder+scRad, tvHeight-tvBorder-scRad, scBack> 
						  <tvBorder+scRad, tvHeight-tvBorder-scRad, scFront> scRad}
				cylinder {<tvWidth-tvBorder-scRad, tvBorder+scRad, scBack> 
						  <tvWidth-tvBorder-scRad, tvBorder+scRad, scFront> scRad}
				cylinder {<tvWidth-tvBorder-scRad, tvHeight-tvBorder-scRad, scBack>
						  <tvWidth-tvBorder-scRad, tvHeight-tvBorder-scRad, scFront> scRad}
				pigment {Blue}
			}
		}
		#if (IncludeWhiteInsert)
			box { 0, 1		// screen insert
				pigment {
					White
	//				image_map {
	//					tga tvPic
	//				}
				}
				finish { emission 1}
				scale <tvWidth-tvBorder*2, tvHeight-tvBorder*2+0.28*inches, 0.1*inches>
				translate <tvBorder, tvBorder-0.33*inches, 0.4*inches>
			}
		#end
		translate y*1*inches
	
	}

object {
	TV
}