// test colonne avec spirales           
#declare Ht=3;   // hauteur de la colonne
#declare Nbt=.5; // Nombre de tours
#declare Nbb=4; // Nombre de pieds
#declare Nbp=100; // Nombre de cylindres sur la hauteur
#declare R1=1; // rayon exterieur de la colonne
#declare R2=.2; // rayon des pieds

#declare Col=union {
        cylinder {<0,Ht,0>,<0,Ht*1.05,0>,R1*1.1}
        cylinder {<0,-Ht*.05,0>,<0,0,0>,R1*1.1}
        #declare Cpt=0;
        #while (Cpt<Nbp)
                #declare Cpt1=0;
                #while (Cpt1<Nbb)
                        cylinder {
                                <0,Cpt*(Ht/Nbp),0>,<0,(Cpt+1)*(Ht/Nbp),0>,R2
                                translate (R1-R2)*x
                                rotate ((360/Nbb)*Cpt1+((360*Nbt)/Nbp)*Cpt)*y
                        }
                        #declare Cpt1=Cpt1+1;
                #end
                #declare Cpt=Cpt+1;
        #end
}

camera {
        location <-5*R1,Ht*1.5,-5*R1>
        look_at <0,Ht/2,0>
}

light_source { <0,Ht,5*R1> color rgb <1,1,1>}
light_source { <0,Ht,-5*R1> color rgb <1,1,1>}
light_source { <-5*R1,Ht,0> color rgb <1,1,1>}
light_source { <5*R1,Ht,0> color rgb <1,1,1>}
light_source { <0,5*Ht,0> color rgb <1,1,1>}

object { Col
        pigment {color rgb <0,.7,.7>}
}