// Persistence of Vision Ray Tracer Scene Description File
// File: .pov
// Vers: 3.5
// Desc: billard 15 balles
// Date: 8 octobre 5h35
// Auth: É.chap


#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "metals.inc"  
#include "glass.inc"  
#include "woods.inc" 

light_source{<-10,10,-10>  color White  }
light_source{<10,12,-20>  color White} 
//light_source{<10,32,20>  color White}  

camera
{
  location  <-10,14,-19 >
  direction 1.5*z
  right     1.5*x
  look_at   <5,1,5>
}  

#declare Ciel   =
sphere {  <0, 0, 0>, 1
  texture { pigment {gradient y color_map { [0.0 color rgb < 1.0, 1.0, 1.0 >] [0.3 color rgb < 0.5, 0.6, 1.0 >] } }
             finish { diffuse 0 ambient 1 }  }
  scale 1000  hollow on  no_shadow
}                      
 
 
#declare Tex_Bois= texture { T_Wood15}
#declare Tex_Metal= texture { Silver_Texture normal { bumps 0.3} scale 0.1}
#declare Tex_Metal= texture { T_Chrome_4A }
#declare Tex_Velour= texture { pigment { Green} normal { waves 0.03} scale 0.1} 
#declare Tex_Velour= texture {   
   pigment {
        granite
        color_map {
            [0.0 rgbf <0,1,0, 0>]
            [0.6 rgbf <0, 0.93, 0, 0>]
            [0.9 rgbf <0, 0.14, 0, 0>]
        }
        }
  scale 0.1
  }
//#declare Tex_Velour= texture { pigment { Green} normal { waves 0.03} scale 0.1} 
  
#declare bande= 
union{
difference
{ box{ 0,<1,1,16>}
  box{ 0,<1,1,16> scale 2 rotate -z*45}
  box{ -y,<1,1.1,3> rotate y*45}
  box{ -y,<3,1.1,3> rotate y*45 translate z*16} 
  texture {Tex_Velour}
    }  
  box { -y,<-2,1,16>  texture { Tex_Bois}}  
  box { -0.1,0.1 rotate <45,45,0> translate <-1,1.1,8> texture{Tex_Metal}}
  box { -0.1,0.1 rotate <45,45,0> translate <-1,1.1,4> texture{Tex_Metal}}
  box { -0.1,0.1 rotate <45,45,0> translate <-1,1.1,12> texture{Tex_Metal}}
  } 
    
  
#declare bandes01=union {
 object { bande}  
 object { bande translate z*18}
 object { bande rotate y*-90 translate <18,0,-2>}
 }
 
#declare coin= 
union {
difference {
  box {<-1,1,-1>,3}
  box { 1,4 }  
  box {-1.4,<1.4,3,1.4> rotate y*45 translate <1.4,1,1.4>}
  box {-1.8,<1.8,3,1.8> rotate y*45 translate <-2,1,-2>}
    } 
  box{ <0,1,-1>,<3,3,0>}
  box{ <-1,1,0>,<0,3,3>}
   texture { Tex_Metal }
   }         
   
#declare coin2=
union {
 difference {
   box { <-1,1,-1>,<1,3,1>}
   box { <-0.6,1,-0.6>,<1.1,4,0.6>}}
   box { <-0.3,1,-0.3>,<0.3,3,0.3> rotate y*45 translate (-x-z)/1.7}
   box { <-0.3,1,-0.3>,<0.3,3,0.3> rotate y*45 translate (-x+z)/1.7}  
   texture { Tex_Metal }
   }
#declare pied =union{
  box { 0,<2,-10,2>}
  box { 0,<6,-2,2>}
  box { 0,<8,-1.5,1.5>}
  box { 0,<9,-1,1>}  
  box { 0,<9.5,-0.5,0.5>}  
  box { 0,<2,-2,6>} 
  box { 0,<1.5,-1.5,8>} 
  box { 0,<1,-1,9>}   
  box { 0,<0.5,-0.5,9.5>} 
  texture { Tex_Bois}
  }   
   
#declare Table=union {  
object { bandes01 translate z*2} 
object { bandes01 rotate y*180 translate <20,0,36>}
object {coin translate <-1,-2,-1>} 
object {coin rotate y*-90 translate <21,-2,-1>} 
object {coin rotate y*90 translate <-1,-2,39>} 
object {coin rotate y*180 translate <21,-2,39>}
object {coin2 translate <-1,-2,19>}  
object {coin2 rotate y*180 translate <21,-2,19> }

object { pied translate <-1,-2,-1>}
object { pied rotate y*-90 translate <19,-2,-1>}
object { pied rotate y*90 translate <-1,-2,39>}
object { pied rotate y*180 translate <19,-2,39>}



difference {
 box{ 0,<20,-2,40> }            
 cylinder { y,-y-y,1.3}
 cylinder { y,-y-y,1.3 translate x*20}
 cylinder { y,-y-y,1.3 translate z*19}
 cylinder { y,-y-y,1.3 translate z*38}
 cylinder { y,-y-y,1.3 translate x*20+z*19}
 cylinder { y,-y-y,1.3 translate x*20+z*38}   
 texture {Tex_Velour}} 
  
 } 
 


object {Table} 
object {Ciel}