//---
#version 3.8;  // ***

#declare BOX_X = 10*(4/3);
#declare BOX_Y = 10;
#declare BOX_Z = 0.5;
#declare MIR_S = 1;
#declare MIR_W = 0.2;

global_settings {
   assumed_gamma 1
   photons { count 100000 media 100, 2 }
}

camera {
   location <BOX_X/2, BOX_Y/2, -10>
   look_at  <BOX_X/2, BOX_Y/2, +10>
}

light_source { // ambient light
   <BOX_X/2, BOX_Y/2, BOX_Z/2>
   color rgb 1
   photons { reflection off refraction off } // ***
   media_interaction off
}

box { // scattering media
   <0, 0, 0>, <BOX_X, BOX_Y, BOX_Z>
   pigment { rgbt 1 }
   hollow
   interior {
      media {
         scattering { 1, 1 extinction 0 }
//       samples 100   // *** Higher samples OK for final render
         samples 7,21  // *** Better performance
      }
   }
   photons { target collect off } // ***
}

light_source { // laser beam
   <0, 0-0.5, BOX_Z/2>  // *** Move light outside media box
   color rgb <0, 1, 0>
   cylinder
   radius 0.01
   falloff 0.2
   point_at <BOX_X, BOX_Y/2, BOX_Z/2>
   photons { reflection on refraction on } // ***
   media_interaction off // *** If on, get (scattering + photons)
                         // *** for light to mirror beam segment.
}

box { // mirror
   <BOX_X-MIR_W-MIR_S, MIR_S, MIR_S>, <BOX_X-MIR_S, BOX_Y-MIR_S, BOX_Z-MIR_S>
   pigment { rgb 1 }
   finish { diffuse 0 emission 0.5 reflection { 1 } } // ***
   photons { target reflection on collect off }  // ***
}
//---