// PoVRay 3.8 Scene File " ... .pov"
// author:  ...
// date:    ...

//--------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
#include "stones.inc"
#include "woods.inc"
#include "shapes.inc"
#include "shapes2.inc"
#include "functions.inc"
#include "math.inc"
#include "transforms.inc"
//--------------------------------------------------------------------------
#version 3.8;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ emission 0 ambient 0.1 diffuse 0.9 }}
//--------------------------------------------------------------------------
// camera ------------------------------------------------------------------
#declare Camera_0 = camera {/*ultra_wide_angle*/ angle 75      // front view
                            location  <0.0 , 2.0 ,-6.0>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , 0.0>}
#declare Camera_1 = camera {/*ultra_wide_angle*/ angle 70   // diagonal view
                            location  <3.0 , 2.5 ,-6.0>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , -2.0>}
#declare Camera_2 = camera {/*ultra_wide_angle*/ angle 90 // right side view
                            location  <3.0 , 1.0 , 0.0>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , 0.0>}
#declare Camera_3 = camera {/*ultra_wide_angle*/ angle 90        // top view
                            location  <0.0 , 3.0 ,-0.001>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , 0.0>}

// sun ---------------------------------------------------------------------
light_source{<1500,2500,-2500> color White}
// sky ---------------------------------------------------------------------
plane{<0,1,0>,1 hollow  
       texture{ pigment{ bozo turbulence 0.76
                         color_map { [0.5 rgb <0.20, 0.20, 1.0>]
                                     [0.6 rgb <1,1,1>]
                                     [1.0 rgb <0.5,0.5,0.5>]}
                       }
                finish {ambient 1 diffuse 0} }      
       scale 10000}
// fog ---------------------------------------------------------------------
fog{fog_type   2
    distance   50
    color      White
    fog_offset 0.1
    fog_alt    2.0
    turbulence 0.8}
// ground ------------------------------------------------------------------
plane { <0,1,0>, 0 
        texture{ pigment{ color rgb<0.35,0.65,0.0>*0.9 }
	         normal { bumps 0.75 scale 0.015 }
                 finish { phong 0.1 }
               } // end of texture
      } // end of plane
//--------------------------------------------------------------------------
//---------------------------- objects in scene ----------------------------
//--------------------------------------------------------------------------

#declare UL = <(-image_width/image_height)/2, 2, -4>;
#declare LR = <(image_width/image_height)/2, 1, -4>;

#declare u_vect = <LR.x, UL.y, LR.z> - UL;
#declare v_vect = <UL.x, LR.y, LR.z> - UL;

#declare tr_base_1=<        0,2/3,0>*0.01;
#declare tr_base_2=< 1/2, -1/3,0>*0.01;
#declare tr_base_3=<-1/2, -1/3,0>*0.01;
#declare camera_mesh = 
mesh {
  #for(V,0,image_height,1)
    #for(U,0,image_width,1)
      #declare here = (UL+u_vect*(U/image_width)+v_vect*(V/image_height));
      triangle { 
        here + tr_base_1, here + tr_base_2, here + tr_base_3
      }
    #end // for U
  #end // for V
} // mesh

// 0 - use mesh camera
// 1 - orthographic equivalent of mesh camera
// 2 - overview of setup
#declare SCENE = 0; 

#switch(SCENE)
#case(0)
camera {
  mesh_camera { 1 0
    mesh { camera_mesh }
  }
  location <0,0,-.1>
  direction z
  //normal { bumps 1 scale 0.1 }
  } 
#break
#case(1)
  camera { orthographic 
    location (UL + LR) / 2
    direction z
    }
#break
#else
  camera{Camera_1}
  object { camera_mesh 
   texture{
    pigment{
      cylindrical poly_wave 2
      color_map{
        [0.2 rgb 0 transmit 0]
        [0.5 rgb 0 transmit 1]
        [1.0 rgb 0 transmit 1]
      }
      rotate 90*x
      scale <image_width/image_height,1,1>
      translate (UL + LR)/2
    } 
    //finish{emission 1}
  }
  hollow no_shadow
  }
  cylinder { UL UL+u_vect 0.01 pigment { red 1 } finish { phong 1 } no_shadow}
  cylinder { UL UL+v_vect 0.01 pigment { green 1 } finish { phong 1 } no_shadow }
#break
#end

// Something to look at
cylinder { <0, 0, 1> <0, 3, 1> 0.5 pigment { rgb <1,1,0> } }