#declare xaxis=40;
#declare zaxis=20;


#declare Plastic =
finish
{
   reflection 0.05
   roughness 0.05
   brilliance 0.3
   phong 0.8
   phong_size 4
}


#declare Shiny_Ball =
sphere
{
   <0, 0, 0>, 1
   pigment
   {
      color rgb <1, 0, 0>
   }
   finish
   {
      Plastic
   }
}


light_source
{
   <-20000, 100000, -60000>
   color rgb 1
}

camera
{
   location <0, 100, 0>
   look_at <0, 0, 0>
}

plane
{
   y, 0
   pigment
   {
      granite
      color_map
      {
         [0     rgb 0.6]
         [0.333 rgb 0.8]
         [0.667 rgb 0.45]
         [1     rgb 0.7]
      }
      turbulence 1.5
      scale 5
    }
    finish
    {
       roughness 1
       brilliance 0
    }
}

#declare i=0;

#while (i<90)
   object
   {
      Shiny_Ball
      #if (clock=0)
      translate <sin(4*i*(pi/180))*xaxis, 1, cos(4*i*(pi/180))*zaxis>
      #end
      #if (clock=1)
      translate <sin(cos(i*8*(pi/180))*360*(pi/180))*xaxis, 1, cos(cos(i*8*(pi/180))*360*(pi/180))*zaxis>
      #end
      #declare i=i+1;
   }
#end