#version 3.7;
global_settings { assumed_gamma 1.0 }

//------------------------------------------
// Macros for generating Scalable Vector Graphic (SVG) files
// Bill Walker - 2016
//------------------------------------------

#include "colors.inc"
#include "debug.inc"
	Set_Debug (true)
#include "math.inc"
#include "rand.inc"
#include "shapes.inc"
#include "shapes3.inc"
#include "transforms.inc"

//###############################################
#declare XImageSize = 1366;
#declare YImageSize = 768;
//###############################################

//  ***** Before raytracing, set render resolution for POV-Ray output file  *****

//#declare YImageSize = -YImageSize;

light_source { <XImageSize/2, -YImageSize/2, -50>  color rgb <1, 1, 1>}

#declare Camera_Origin = camera {
                            location  <0, 0, 0>
                            //right    x*image_width/image_height
                            look_at   <0, 0, 0.01>}

#declare Camera_Angle = camera {
                            location  <5 , 10, -15.0>
                            //right    x*image_width/image_height
                            //look_at   <0, 0, 0>
                            look_at   <5, 5, 5>}
#declare Camera_Front = camera {
                            location  <XImageSize/2, -YImageSize/2, -max(XImageSize, YImageSize)>
                            //right    x*image_width/image_height
                            look_at   <XImageSize/2, -YImageSize/2, 0>}
#declare Camera_Rear = camera {
                            location  <0.0, -100.0, -300.0>
                            //right    x*image_width/image_height
                            look_at   <0, 0, 0>}
#declare Camera_Top = camera {
                            location  <0, 8.0, 0>
                            //right    x*image_width/image_height
                            look_at   <0, 0, 0>}

#declare Camera_Iso = camera {
                            location  <-50, 0, 0>
                            //right    x*image_width/image_height
                            look_at   <0, 0, 0>}

#declare Camera_Bottom = camera {
                            location  <0, -1, -0.1>
                            //right    x*image_width/image_height
                            look_at   <0, 0, 0>}                            

#declare Camera_Point = camera {
                            location  <1.5, 0, -1>
                            //right    x*image_width/image_height
                            look_at   <1.5, 0, 0>}

#declare Camera_Orthographic = camera {
                            orthographic
                            location <XImageSize/2, -YImageSize/2, -10>
                            sky <0, 1, 0>
                            right <XImageSize, 0, 0>
                            up <0, YImageSize, 0>
                           
                            look_at <XImageSize/2, -YImageSize/2, 1>}  // having z=1 here seems to be be important for the ortho camera to work properly
                            
camera {Camera_Orthographic}

sky_sphere { pigment {White} }

//======================================================================================================================= 
//plane { <0,1,0>, 0  texture { pigment{color Black}} }
cylinder { <-1366, 0, 0>, <1366, 0, 0>, 5 pigment {color Red}}   // X-axis
cylinder { <0, 0, -768>, <0, 0, 768>, 5 pigment {color Red}}	// Y-axis
#declare Zplane = 100;
#declare Layer = 0.01;


#ifndef (SVG_File)
#fopen SVG_File "POV-SVG_Test1.svg" write
#end

// Write svg file header
// <svg xmlns="http://www.w3.org/2000/svg" version="1.1"  width="1366" height="768" >
#write (SVG_File, "<svg xmlns=\"http://www.w3.org/2000/svg\" version=\"1.1\" width=\"", XImageSize, "\" height=\"", YImageSize, "\" >")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "<!-- SVG Drawing generated by POV-Ray v 3.7, Macros written by Bill Walker (Bald Eagle) -->")  //  SVG COMMENT
#write (SVG_File, "\n")  //  Line break
//######################################################################################
//                              BEGIN OBJECT DEFINITIONS
//######################################################################################

// LINE
#write(SVG_File, "<!-- Line -->")  //  SVG COMMENT
#write(SVG_File, "\n")  //  Line break

// define attributes for object
// <line x1="250" y1="50" x2="400" y2="200" stroke="blue" stroke-width="4" />
#local Object = "line";
#local X1 = 250;
#local Y1 = 50;
#local X2 = 400;
#local Y2 = 200;
#local Stroke_width = 4;
#local Stroke = "blue";
#local LineColor = pigment {Blue};

// write Line to file
#write (SVG_File,"<", Object, " x1=\"", X1, "\" y1=\"", Y1, "\" x2=\"", X2, "\" y2=\"", Y2, "\" stroke-width=\"", Stroke_width, "\" stroke=\"", Stroke, "\" />")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "\n")  //  Line break

// Define analogous objects in POV-Ray
cylinder {<X1, -Y1, Zplane-(2*Layer)>, <X2, -Y2, Zplane-(2*Layer)> Stroke_width/2 texture {LineColor}}

//============================SVG Object Separator=====================================

// POLYLINE
#write (SVG_File, "<!-- Polyline -->")  //  SVG COMMENT
#write (SVG_File, "\n")  //  Line break

// define attributes for object
// <polyline points="250,150 250,200 400,200 400,100" stroke="red" stroke-width="4" fill="none" />
#local Object = "polyline";
// NUMBER OF POINTS
#local Points = 4;
#local Polyline = array [Points] {<250, 150, Zplane>, <250, 200, Zplane>, <400, 200, Zplane>, <400, 100, Zplane> };
#local Elements = dimension_size (Polyline, 1);
#local Fill = "none";
#local Stroke_width = 4;
#local Stroke = "red";
#local LineColor = pigment {Red};

// write polyline to file
#write (SVG_File, "<", Object, " points=\"")
#local loop = 0;
#while (loop < Elements)
	#local Vector = Polyline [loop];
	#write (SVG_File, Vector.x, ",", Vector.y, " " )
	// Define analogous objects in POV-Ray
	#if (loop = 0)
	#else
	cylinder {<Lastvector.x, -Lastvector.y, Zplane-(2*Layer)>, <Vector.x, -Vector.y, Zplane-(2*Layer)> Stroke_width/2 texture {LineColor}}
	#end
	#local Lastvector = Vector;
	#local loop = loop + 1;
#end // end while

#write (SVG_File, "\" stroke=\"", Stroke, "\" stroke-width=\"", Stroke_width, "\" fill=\"", Fill, "\" />")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "\n")  //  Line break


//============================SVG Object Separator=====================================

// RECTANGLE
#write(SVG_File, "<!-- Rectangle -->")  //  SVG COMMENT
#write(SVG_File, "\n")  //  Line break

// define attributes for object
// <rect x="25" y="20" width="200" height="200" fill="lime" stroke-width="4" stroke="pink" />
#local Object = "rect";
#local X = 25;
#local Y = 20;
#local Width = 200;
#local Height = 200;
#local Fill = "lime";
#local Stroke_width = 4;
#local Stroke = "pink";
#local Color = pigment {color rgb <0, 0, 0>};

// write rectangle to file
#write (SVG_File,"<", Object, " x=\"", X, "\" y=\"", Y, "\" width=\"", Width, "\" height=\"", Height, "\" fill=\"", Fill, "\" stroke-width=\"", Stroke_width, "\" stroke=\"", Stroke, "\" />")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "\n")  //  Line break

// Define analogous objects in POV-Ray
box {<X, -Y, Zplane> 	    <X+Width, -(Y+Height), Zplane+Layer> pigment {Red}}	// Large red box for outline
box {<X+Stroke_width, -(Y+Stroke_width), Zplane-Layer> <X+Width-Stroke_width, -(Y+Height-Stroke_width), Zplane> pigment {Green}}	// Smaller inset box for fill

//============================SVG Object Separator=====================================

// Rounded Corner Rectangle
#write (SVG_File, "<!-- Rounded corner rectangle -->")  //  SVG COMMENT
#write (SVG_File, "\n")  //  Line break
// define attributes for object
//<rect x="250" y="20" rx="20" ry="20" width="150" height="150" style="fill:red;stroke:black;stroke-width:5;opacity:0.5" />
#local Object = "rect";
#local X = 250;
#local Y = 20;
#local RX = 20;
#local RY = 20;
#local Width = 150;
#local Height = 150;
#local Fill = "red";
#local Stroke_width = 5;
#local Stroke = "black";
#local Color = pigment {color rgb <0, 0, 0>};

// write rounded rectangle to file
#write (SVG_File,"<", Object, " x=\"", X, "\" y=\"", Y, "\" rx=\"", RX, "\" ry=\"", RY, "\" width=\"", Width, "\" height=\"", Height, "\" fill=\"", Fill, "\" stroke-width=\"", Stroke_width, "\" stroke=\"", Stroke, "\" />")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "\n")  //  Line break

// Define analogous objects in POV-Ray

// Corner
#local Corner = object {Segment_of_Torus (RX, Stroke_width/2, -90) texture {Color}}
      			
#local TL = object {Corner rotate <0, -90, 0> rotate <-90, 0, 0> scale <1, RY/RX, 1> translate <X+RX, -(Y+RY), Zplane>}
#local TR = object {Corner rotate <0, 0.0, 0> rotate <-90, 0, 0> scale <1, RY/RX, 1> translate <X+(Width-RX), -(Y+RY), Zplane>}
#local BL = object {Corner rotate <0, -180, 0> rotate <-90, 0, 0> scale <1, RY/RX, 1> translate <X+RX, -(Y+(Height-RY)), Zplane>}
#local BR = object {Corner rotate <0, 90, 0> rotate <-90, 0, 0> scale <1, RY/RX, 1> translate <X+(Width-RX), -(Y+(Height-RY)), Zplane>}
#local Top =    cylinder {<X+RX, -Y, Zplane>, 		<X+(Width-RX), -Y, Zplane> 		 Stroke_width/2 texture {Color}}
#local Bottom = cylinder {<X+RX, -(Y+Height), Zplane>, <X+(Width-RX), -(Y+Height), Zplane> Stroke_width/2 texture {Color}}
#local Left =   cylinder {<X, -(Y+RY), Zplane>, 		<X, -(Y+(Height-RY)), Zplane> 	 Stroke_width/2 texture {Color}}
#local Right =  cylinder {<X+Width, -(Y+RY), Zplane>, 	<X+Width, -(Y+(Height-RY)), Zplane> Stroke_width/2 texture {Color}}

#local RoundedRectangle = union { 
object {TL}
object {TR}	
object {BL}
object {BR}
object {Top}	
object {Bottom}
object {Left}
object {Right}				}

object {RoundedRectangle}

//============================SVG Object Separator=====================================

// CIRCLE
#write(SVG_File, "<!-- circle -->")  //  SVG COMMENT
#write(SVG_File, "\n")  //  Line break
// define attributes for object
// <circle cx="125" cy="125" r="75" fill="orange" />
#local Object = "circle";
#local X = 125;
#local Y = 125;
#local Radius = 75;
#local Fill = "orange";
#local FillColor = pigment {Orange};
#local Stroke_width = 1;
#local Stroke = "black";
#local LineColor = pigment {Black};

// write circle to file
#write (SVG_File,"<", Object, " cx=\"", X, "\" cy=\"", Y, "\" r=\"", Radius, "\" fill=\"", Fill, "\" stroke-width=\"", Stroke_width, "\" stroke=\"", Stroke, "\" />")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "\n")  //  Line break

// Define analogous objects in POV-Ray
torus { Radius, Stroke_width/2 texture {LineColor} scale <1, 1, 1> rotate<90, 0, 0> translate<X, Y, Zplane-(2*Layer)>}         
disc {<X, -Y, Zplane-(2*Layer)>, <0, 0, 1>, Radius, 0 texture {FillColor}}
//cylinder {<X, -Y, Zplane-(2*Layer)>, <X, -Y, Zplane> Radius texture {FillColor}}

//============================SVG Object Separator=====================================

// Ellipse
#write(SVG_File, "<!-- Ellipse -->")  //  SVG COMMENT
#write(SVG_File, "\n")  //  Line break
// define attributes for object
// <ellipse cx="50" cy="350" rx="25" ry="50" fill="yellow" stroke="purple" stroke-width="4" />
#local Object = "ellipse";
#local X = 50;
#local Y = 350;
#local RX = 25;
#local RY = 50;
#local Fill = "yellow";
#local FillColor = pigment {Yellow};
#local Stroke_width = 4;
#local Stroke = "purple";
#local LineColor = pigment {Violet};

// write ellipse to file
#write (SVG_File,"<", Object, " cx=\"", X, "\" cy=\"", Y, "\" rx=\"", RX, "\" ry=\"", RY, "\" fill=\"", Fill, "\" stroke=\"", Stroke, "\" stroke-width=\"", Stroke_width, "\" />")
#write (SVG_File, "\n")  //  Line break
#write (SVG_File, "\n")  //  Line break

// Define analogous objects in POV-Ray
torus { 100, Stroke_width/2 scale <RX/100, 1, RY/100> rotate<90, 0, 0> translate <X, -Y, Zplane-(2*Layer)> texture {LineColor} }         
disc {<0, 0, 0>, <0, 0, 1>, 100, 0 scale <RX/100, RY/100, 1> translate <X, -Y, Zplane-(2*Layer)> texture {FillColor}}
//cylinder {<X, -Y, Zplane-(2*Layer)>, <X, -Y, Zplane> Radius texture {FillColor}}

//============================SVG Object Separator=====================================

// PATH

//  <path id="lineAB" d="M 920 350 l 150 -300" stroke="red" stroke-width="3" fill="none" />
//  <path id="lineBC" d="M 1070 50 l 150 300" stroke="red" stroke-width="3" fill="none" />
//  <path d="M 995 200 l 150 0" stroke="green" stroke-width="3" fill="none" />
//  <path d="M 920 350 q 150 -300 300 0" stroke="blue" stroke-width="5" fill="none" />

//######################################################################################
//                               END OBJECT DEFINITIONS
//######################################################################################
// write end of SVG file
#write(SVG_File,"</svg>")

#fclose SVG_File