// Code for "Dancing Sticks"
// INI setting were: 640x480, AA=.03, Final_Frame=8, +KC 
// animated gif assembled using ULead 2.0 (freeware)

global_settings {max_trace_level 5}

camera {location <0, 9, -25>
        direction <0, 0, 4.5>
        right x*1.33
        look_at <0,1.8,0>
}
                         
                         
light_source{<-20,80,-40> rgb 1} 

sky_sphere {pigment { gradient y 
   color_map {[ 0.0  rgb <.7,.7,.9>]
              [ 0.5  rgb <.5,.5,.7>]
              [ 1.0  rgb <.7,.7,.9>] }} 
   rotate x*-15
}


box{<-5,-.5,-5>,<5,0,5> 
   texture{
      pigment{checker rgb<.95,.9,.8> rgb<.9,.85,.7>}
      finish{ambient .3 diffuse .5 reflection .2}
   scale .1}
}

// Variables:
//   BUR is Basic Unit Radius
//   YAR is Y-axis Rotation 
//   NSR is Number of Sphere Rotations

#declare BUR = .02; #declare NSR=300; 


#declare YAR =0; #while (YAR<360*NSR)

sphere{0,BUR 
  texture{ 
     pigment{ color rgb<1.2,1.1,.95> }
     finish{ambient .4 diffuse .8 reflection .1 phong .8 phong_size 45 }
   }
   translate <2+.6*cos(radians(YAR)*3.001) +.6*sin(radians(YAR)*2.999),
      BUR+(YAR-2*clock)*.000035,0> 
   rotate <0,(YAR-2*clock),0>
} 

#declare YAR=YAR+2;  #end