// First post in POVRay forumns. Created by Evan Trask
// Feel free to modify and render as you please

// INCLUDES

// DECLARES
#default {
  texture {
    pigment { color rgb <0.8,0.8,0.8> }
    finish {
      ambient 0
      diffuse 1
    }
  }
}

#declare xIteration = 0;
#declare yIteration = 0;
#declare numColumns = 100;
#declare colSpacing = 1.5; // Distance from center to center of each column

#declare b = ((numColumns-1)*(colSpacing)+100)/2; // b in y=mx+b
  
// GLOBAL SETTINGS
global_settings {
  radiosity {
    adc_bailout 1/256
    brightness 1.25
    count 100
    error_bound 0.4
    gray_threshold 0
    low_error_factor 0.9
    minimum_reuse 0.025
    nearest_count 5
    pretrace_start 0.25
    pretrace_end   25/(image_width*image_height)
    recursion_limit 1
  }
}

// CAMERA
camera {
  location <-3,15,-5>
  right (image_width/image_height)*x
  up y
  look_at <0,10+(sin(degrees(50+50))),0>
}

// LIGHTS
light_source {
  <0,25,-b>
  color rgb <1,1,1>
  area_light <1,0,0>, <0,1,0>, 10, 10
  jitter
  parallel
  rotate y*(rand(seed(1969)))
}

// SCENE
union {
  #while ( xIteration < numColumns )
    #while ( yIteration < numColumns )
      box {
        <-0.5,0.0001,-0.5>
        <0.5,10,0.5>
        translate <xIteration*colSpacing-b,sin(degrees(xIteration+yIteration)),yIteration*colSpacing-b>
      }
      #declare yIteration = yIteration + 1;
    #end
    #declare yIteration = 0;
    #declare xIteration = xIteration + 1;
  #end
}
sky_sphere {
  pigment {
    bozo
    turbulence 0.25
    octaves 7
    lambda 9
    omega 0
    color_map {
      [ 0.00 color rgb <0.196078,0.196078,0.800000> ] // Medium Blue
      [ 0.115 color rgb <0.196078,0.196078,0.800000> ] // Medium Blue
      [ 0.50 color rgb <0.258824,0.258824,0.435294> ] // CornFlower Blue
      [ 0.80 color rgb <1.000000,0.500000,0.000000> ] // Orange
      [ 0.99 color rgb <1.000000,0.500000,0.000000> ] // Orange
    }
    scale <5,1,1>
  }
}
sphere {
  <0.25,10+(sin(degrees(50+50))),0.25>
  0.5
  texture {
    pigment { color rgb <1,1,1> }
    finish {
      ambient 0
      diffuse 1
      reflection {
        0.5, 1
        fresnel on
      }
    }
  }
}