camera {
  location <0,100,-1000>
  look_at <0,100,0>
  angle 60
}

light_source { <500,1000,-1000> rgb 1}

#declare fin = finish {reflection 0.1 specular 0.5 metallic};
#declare col = color rgb 1;

#declare t0 = texture {
  pigment {col}
  finish {fin}
};
#declare t1 = texture {
  pigment {bozo scale 50 rotate y*0 color_map {[0 col] [1 rgbt <1,1,1,1>]}}
  normal { pigment_pattern {waves warp {repeat x*100} color_map {[0, rgb 0][1, rgb 1]} translate 0 scale 3} 10}
  finish {fin}
};
#declare t2 = texture {
  pigment {bozo scale 50 rotate y*30 color_map {[0 col] [.8 rgbt <1,1,1,1>]}}
  normal { pigment_pattern {waves warp {repeat y*100} color_map {[0, rgb 0][1, rgb 1]} translate 30 scale 3} 10}
  finish {fin}
};
#declare t3 = texture {
  pigment {bozo scale 50 rotate y*70 color_map {[0 col] [.7 rgbt <1,1,1,1>]}}
  normal { pigment_pattern {waves warp {repeat z*100} color_map {[0, rgb 0][1, rgb 1]} translate -30 scale 3} 10}
  finish {fin}
};

#declare metal = 
texture {t0}
texture {t1}
texture {t2}
texture {t3};

sphere {<300,200,0>, 200 texture {metal}}
cylinder {<-400,200,0>,<0,200,600>, 200 texture {metal}} 
plane {y,0 texture {metal}}
cone {<0,0,-100>, 150, <0,350,-100>, 0 texture {metal}} 

sky_sphere {
  pigment {
    gradient y
    color_map {[0 rgb 1] [.5 rgb <0,0.3,1>]}
  }
}