// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7
// Copyright 2003 by Tor Olav Kristensen
// Email: t o r _ o l a v _ k [ a t ] h o t m a i l [ d o t ] c o m
// http://home.no/t-o-k
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

// File: MountainIso_HeightMap.pov

// Sample command line switches: +FT +w1024 +h768

#version 3.5;

#include "MountainIso.inc"

global_settings {
  assumed_gamma 1
  hf_gray_16
}

default {
  finish {
    ambient color rgb <1, 1, 1>
    diffuse 0
  }
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

#declare vSize = pMax - pMin;

#declare HeightPigment =
  pigment {
    gradient y
    color_map {
      [ 0 color rgb <0, 0, 0> ]
      [ 1 color rgb <1, 1, 1> ]
    }
    scale vSize
    translate pMin
  }

object { IsoMountains pigment { HeightPigment } }

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

#declare pMid = (pMin + pMax)/2;

camera {
  orthographic
  right vSize*x
  up vSize*z
  direction -y
  translate pMid + 100*y
}

background { color rgb <0.3, 0.8, 1.0> }

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7