// Persistence of Vision Ray Tracer Scene Description File
// File: OrangePill.pov
// Vers: 3.5
// Desc: The Orange Pill - Photons & caustics test
// Date: 2003.09.06
// Auth: Alain Ducharme
//

#version 3.5;

#declare Photons=on;
#declare Radiosity=off;

global_settings {
  assumed_gamma 1.0
  max_trace_level 5
  #if (Photons)
    photons {
      spacing 0.015
    }
  #end
  #if (Radiosity)
    radiosity {
      pretrace_start 0.08
      pretrace_end   0.01
      count 200
    }
  #end  
}

camera {
  location  <0.0, 1.0, -2.0>
  angle     53
  right     x*image_width/image_height
  look_at   <0.0, 0.25,  0.0>
}

#declare LightPanel = box { <-0.5,1,-0.5>, <0.5,1.1,0.5>
  texture { pigment { color rgb 1 } finish { ambient 2 } }
}
light_source {
  <0,1,0>
  color rgb <1,1,1>
  fade_distance 1
  fade_power 3
  area_light <1,0,0> <0,0,1>, 10, 10 adaptive 1 jitter
  // looks_like { LightPanel }   // Not needed
  photons {
    refraction on
    reflection on
    // area_light     // Better caustics without!
  }
}

plane {
  y, -0
  texture { pigment { color rgb <1,1,1> } finish { ambient 0 } }  
}

#declare Orangy = material {
  texture {
    pigment { color rgbt 1 }
    finish {
      ambient 0
      diffuse 0
      reflection { 0.1, 1.0 fresnel on }
      specular 0.5
      roughness 1
      conserve_energy
    }
  }
  interior {
    ior 1.5
    fade_power 1001
    fade_distance 0.2
    fade_color <1, 0.6, 0.1>
    //dispersion 1.001
    //dispersion_samples 10
    //caustics 1
  }
}

merge {
  cylinder { <-0.5,0.25,0>, <0.5,0.25,0>, 0.25
    open }
  sphere { <-0.5,0.25,0>, 0.25 }
  sphere { <0.5,0.25,0>, 0.25 }
  material { Orangy }
  photons {
    target 1.0
    refraction on
    reflection on
  }
  translate <0,0.25,0>
//  rotate y*(clock*180)
}

cylinder { <0,0,0>, <0,0.25,0>, 0.1
  texture { pigment { color rgb 1 } finish { ambient 0 } }
}  

text {
  ttf "Arial.ttf" "The OranGe Pill" 0.1, 0
  texture {
    pigment { color rgb <1,1,1> }
    #if (Radiosity)
      finish { ambient 0.0 }
    #end
  }  
  scale 0.25
  translate <-0.90,0.005,-0.4>
  rotate <0,30,0>
}