// Persistence of Vision Ray Tracer Scene Description File
// File: ublob4.pov
// Vers: 3.5
// Desc: Painter's palette
// Date: 07/27/2002
// Auth: Simone Lazzaris (ziopera)
//

#version 3.5;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  <0.0, 2.5, -4.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  looks_like { sphere {0,5 pigment {color rgb <15,15,0>} } }
  translate <-30, 30, -30>
}

//---------------------------------------------------------------------------
#declare seed90=seed(90);

#macro boxText( bwFlag )

 #local baseRotate = rand(seed90)*20;
 texture {
  pigment { color rgb 0.5*<.85,.9,1> }
  finish { ambient .3 diffuse .5 specular 0.7 roughness .05 reflection .36  }
  normal { bumps .5 scale <.5,.015,.015> }
  rotate z*baseRotate
  scale 4
 }
 texture {
  pigment { color rgbf <.5,.5,.5,.75>/*<1,1,1,.75>*/ }
  finish { ambient .3 diffuse .5 specular 0.7 roughness .05 reflection .36 }
  normal { bumps .5 scale <.65,.015,.015> }
  rotate z*baseRotate
  rotate z*60
  scale 4
 }
 #if( bwFlag = 1 )
 texture {
  pigment { color rgbf <.1,.2,.4,.75> }
  finish { ambient .3 diffuse .5 specular 0.7 roughness .05 reflection .36 }
  normal { bumps .5 scale <.75,.015,.015> }
  rotate z*baseRotate
  rotate z*-85
  scale 4
 }
 #else
 texture {
  pigment { color rgbf <.85,.9,1,.75> }
  finish { ambient .3 diffuse .5 specular 0.7 roughness .05 reflection .36 }
  normal { bumps .5 scale <.5,.015,.015> }
  rotate z*baseRotate
  rotate z*-105
  scale 4
 }
 #end

#end


plane {
  y, -1
  boxText( 1 )
} 

//---------------------------------------------------------------------------
#declare txtRed=texture {
    pigment { color rgb <1,0,0> }//rgb <1, .125, .125> }
    finish { specular 1 roughness .005 reflection { .125, .5 } }
    }
                                                            
#declare txtGreen=texture {
    pigment { color rgb <0, 1, 0> }
    finish { specular 1 roughness .0025 reflection { .125, .5 } }
    }

#declare txtBlue=texture {
    pigment { color rgb <0, 0, 1> }
    finish { specular 1 roughness .005 reflection { .125, .5 } }
    }
#declare txtYellow=texture {
    pigment { color rgb <1, 1, 0> }
    finish { specular 1 roughness .005 reflection { .125, .5 } }
    }
//---------------------------------------------------------------------------
#declare rr=seed(1768);

#macro xrand(rx)
(rx*(rand(rr)-0.5))
#end
//---------------------------------------------------------------------------
#macro spot(xx,yy,txt)
   #declare ii=0;
   #while (ii<15)
   sphere {
      <xx+xrand(2),-1.85,yy+xrand(2)>, 0.5+rand(rr)*0.5, 0.5+rand(rr)*0.5
      texture{txt}
      }      
   #declare ii=ii+1;
   #end  
#end              


#declare AREA=60;              
#declare ITERA=250;
blob {                                                            
#declare tt=0;
#while (tt<ITERA)              
spot(xrand(AREA),xrand(AREA)+AREA/2,texture{txtRed} )
spot(xrand(AREA),xrand(AREA)+AREA/2,texture{txtGreen})
spot(xrand(AREA),xrand(AREA)+AREA/2,texture{txtBlue})
spot(xrand(AREA),xrand(AREA)+AREA/2,texture{txtYellow})
#declare tt=tt+1;
#end
threshold 1
scale <1,0.5,1>
}

#declare AREA2X=30;              
#declare AREA2Z=10;              
#declare ITERA2=50;

blob {                                                            
#declare tt=0;
#while (tt<ITERA2)              
spot(xrand(AREA2X),xrand(AREA2Z)-AREA2Z/2-2,texture{txtRed} )
spot(xrand(AREA2X),xrand(AREA2Z)-AREA2Z/2-2,texture{txtGreen})
spot(xrand(AREA2X),xrand(AREA2Z)-AREA2Z/2-2,texture{txtBlue})
spot(xrand(AREA2X),xrand(AREA2Z)-AREA2Z/2-2,texture{txtYellow})
#declare tt=tt+1;
#end
threshold 1
scale <1,0.5,1>
}

//---------------------------------------------------------------------------
sphere {          
   <0.45,-0.75,3> ,0.25
   texture {
      pigment {rgb 0.15}
      finish {specular 1 reflection {0.6} metallic}
      }
   }

sphere {          
   <1.6,-0.75,1.15> ,0.25
   texture {
      pigment {rgb 0.35}
      finish {specular 1 reflection {0.6} metallic}
      }
   }

sphere {          
   <-1.2,-0.75,-0.5> ,0.25
   texture {
      pigment {rgb 0}
      finish {specular 1 reflection {0.6} metallic}
      }
   }
//---------------------------------------------------------------------------   

#declare P_Clouds1=
pigment {  
       bozo 
       color_map {      
         [0.3 color rgbt < 0.91, 0.96, 0.99, 0.0>]  
         [0.5 color rgbt < 0.91, 0.96, 0.99, 1.0>]               
       }    
       turbulence 0.85
       lambda 2.8
       omega 0.6  
       octaves 8
       scale <0.5,0.5,0.2> 
}      
      
#declare Sky_Bckg_13 = 
texture {    
   pigment {      
     gradient y //gradient z
     color_map {   
       [0.0 color rgb < 0.780, 0.835, 0.976 >]  
       [0.27 color rgb < 0.300, 0.450, 0.950 >]        
     } 
     turbulence 0.05            
   } 
   finish { diffuse 0 ambient 1 }                    
}        
texture {
   pigment { P_Clouds1 }  
   finish { diffuse 0 ambient 1 }  
}

sphere { 
  <0, 0, 0>, 1      
  texture { 
     Sky_Bckg_13  
     //rotate -20*x
  }  
  scale<100, 20, 100>//scale<1000, 1000, 200>     
  no_shadow 
  hollow on 
}