//stone test for Orchid XP v3

global_settings {
	assumed_gamma 1
	number_of_waves 10
	//^ this controls how many seperate points the ripples radiate from within a unit box at the origin,
	//so the more we have the more box-shaped the waves should be. I think.
}

superellipsoid {
	<.1,.1>
	pigment {
		granite poly_wave 1/5
		scale 1/30 warp { turbulence .5 octaves 3 } scale 30
		scale 2
		colour_map { [0 rgb <.4,.1,0>][1 rgb 1] }
	}
	finish { diffuse 1 ambient .3 phong .4 phong_size 200 }
}

plane {
	y, 0
	
	pigment{rgbt 1}
	finish{reflection{0,1 fresnel} conserve_energy}
	interior{ior 1.33 fade_colour<0,.1,.2> fade_power 2 fade_distance 1}
	normal {
		pigment_pattern {
			spherical
			scale 6
			colour_map { [0 rgb 0][5/6 rgb 1] }
		}
		poly_wave 2
		normal_map {
			[0 bozo 0] //flat
			[1
				ripples 2
				//according to pov's docs ripples start in the <0,0,0> to <1,1,1> box,
				//but it looks like they're actually <-1,-1,-1> to <1,1,1> which matches my cube! :)
				frequency 8
			]
		}
	}
}
//sea bed, smooth pebbles
plane {
	y,-1
	pigment {
		crackle solid
		scale .3 //line up with the normal
		pigment_map {
			[0 rgb <1,.9,.7>]
			[.9 rgb <.7,.5,.3>]
			[1 rgb <.4,.2,.0>]
		}
	}
	finish { diffuse .7 ambient .3 phong .8 phong_size 100 metallic 1 }
	normal { crackle -1 form <1,0,0> poly_wave 2 scale .3 }
}

sky_sphere {
	pigment {
		planar
		poly_wave 2
		colour_map {
			[0 rgb <.1,.2,.4>]
			[1 rgb <.5,.8,1>]
		}
	}
}

light_source { 9, 1 }

camera {
	translate -z*5
	rotate 30*x	
	rotate -30*y
}