#include "functions.inc"
#include "rand.inc"
#include "screen.inc"

Set_Camera_Location (<0,1,-10>)
Set_Camera_Look_At (<0,0,0>)
Set_Camera_Sky(vrotate(y,z*10))


#declare rs=seed(3457+4); // play with this to get varying backgrounds
#macro random_bar()
 #local n=VRand_On_Sphere(rs);
 #local nx=n.x;
 #local ny=n.y;
 #local nz=n.z;
 #local c=rand(rs)*2-1;
 #local w=rand(rs)*0.2+0.0;   // change this to vary the width distribution of the stripes
 #local frq=int(rand(rs)*6)+1;
 #local phs=rand(rs)*2*pi;
  ((nx*x+ny*y+nz*z)>c-w/2 & (nx*x+ny*y+nz*z)<c+w/2)*(sin(f_th(x,y,z)*frq+phs)/2+0.5)
#end

#declare P_bg=pigment {
 function{
  #local num=30; // Change to more or less...
  #local i=0;
   #while(i<num)
    random_bar()/num*6+   // Adjust the factor 6 to get an unclipped image
    #local i=i+1;
   #end
  0
 }
 color_map {  // play with the colors...
  [0 color rgb <0.1,0.1,0.4>]
  [0.5 color rgb <0.1,0.2,1>]
  [1 color rgb 1]
 }
}

sky_sphere {
 pigment {
  P_bg
 }                        
}     

#local grid=10;    // grid spacing
#local line=0.06;  // line width

plane {
 y,-10
 texture {
  pigment {
   boxed
   translate <1,0,1>
   scale grid/2
   translate -10*y

   warp { repeat grid*z }
   warp { repeat grid*x }

   rotate y*34
   color_map {
    [line rgb <1,0.2,0.05>]
    [2*line rgb <1,0.6,0.4>*0.05]
   }         
  }
  finish {
   ambient 1
   reflection {0,1}
  }
 }
}


#declare textobject=text {
 ttf 
  "computerfont regular.ttf"   // You may have to replace the font, or google it up!
  "l33t haXX0r"
  0.01,0
 pigment {
  gradient -y
  scale 0.61         // matched for the used font
  translate -y*0.06  //     ------ " ---------
  color_map{   // this is the "Chrome" effect colormap
   [0 rgb <0.4,0.4,0.45>*0.7]
   [0.6 rgb <0.9,0.9,0.99>]
   [0.61 rgb <0.5,0.4,0.3>*1]
   [0.99 rgb <0.9,0.89,0.87>]
  }
 } 
 finish { ambient 1}
 scale <0.15,0.1,0.1>*1.2
}                        

Screen_Object(textobject,<1,0>,<0.1,0.03>,true,0.1)

light_group{  // The shiny sphere is is the only object, that gets lit by a real light source...

 light_source {
  <-1,1,-2>*10000
  color rgb 1
 }

 sphere {
  <-20,8.5-10+0.5,50>,8.5
  texture {
   pigment { color rgb <0.5,0.50,0.55>}
   finish { 
    ambient 0.0 
    diffuse 1
    reflection { 0.2,0.7}
    phong 0.5
    phong_size 2
   }
  }
 } 

}

// Have fun!