// Persistence of Vision Ray Tracer Scene Description File
// File: brooch.pov
// Vers: 3.6
// Desc: Inspired by a brooch by T.J.Lechtenberg
//       Appearig in Lapidary Journal, Sep 2004, page 29
// Date: 23 October 2004
// Auth: Joseph Jaquinta
//

#version 3.6;

#include "colors.inc"
#include "glass.inc"
#include "golds.inc"

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  <0.0, 0.5, -3.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------

plane {
  z, 10
  pigment { Black }
}

#declare ring_rad1=1.0;
#declare ring_rad2=0.8;
#declare ring_thick=0.25;

#declare pin_length=.50;
#declare pin_length_delta=.20;
#declare pin_rad=.008;
#declare pin_ball_rad=.012;
#declare pin_num=100;

#declare rnd=seed(0);

// derived
#declare ring_pen_rad=(ring_rad1*2+ring_rad2)/3;
#declare pin_gap=2*pi*ring_pen_rad/pin_num;
#declare pin_x_delta=pin_gap/4;
#declare pin_y_delta=(ring_rad1-ring_rad2)/8;
#declare pin_z_delta=ring_thick/8;

#declare pin_xrot_delta=2;
#declare pin_zrot_delta=2;

union
{

  difference
  {
    cylinder { <0,0,-ring_thick/2>, <0,0,+ring_thick/2>, ring_rad1 }
    cylinder { <0,0,-ring_thick>, <0,0,+ring_thick>, ring_rad2 }
    texture { T_Old_Glass } 
  }

  #local i = 0;
  #while (i < pin_num)
    #local len=pin_length+(rand(rnd)*2*pin_length_delta - pin_length_delta);
    union
    {
      cylinder { <0,0,0>, <0,-len,0>, pin_rad }
      sphere { <0,-len,0>, pin_ball_rad }
      texture { T_Gold_4C }
      rotate <rand(rnd)*pin_xrot_delta*2-pin_xrot_delta,0,rand(rnd)*pin_zrot_delta*2-pin_zrot_delta>
      translate <rand(rnd)*pin_x_delta*2-pin_x_delta,rand(rnd)*pin_y_delta*2-pin_y_delta,rand(rnd)*pin_z_delta*2-pin_z_delta>
      translate y*ring_pen_rad
      rotate z*i*360/pin_num
    }
  
    #local i = i + 1;
  #end

  scale <1.2,.8,1>
  rotate x*30  
}