#include "colors.inc"
#include "functions.inc"
#include "stars.inc"

// radiosity (global illumination) settings
global_settings {
  radiosity {
    pretrace_start 0.08           // start pretrace at this size
    pretrace_end   0.04           // end pretrace at this size
    count 10                      // higher -> higher quality (1..1600) [35]
    nearest_count 3               // higher -> higher quality (1..10) [5]
    error_bound 1.5               // higher -> smoother, less accurate [1.8]
    recursion_limit 3             // how much interreflections are calculated (1..5+) [3]
    low_error_factor .5           // reduce error_bound during last pretrace step
    gray_threshold 0.0            // increase for weakening colors (0..1) [0]
    minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
    brightness 1                  // brightness of radiosity effects (0..1) [1]

    adc_bailout 0.01/2
  }
}



camera { location <5, 1, -30> look_at <0,0,0> angle 30 rotate z*2}
light_source { < 100, 100, -100> color White }
light_source { <-100, 100, -100> color White }

#declare fn_Pigm=function {
				pigment {
					agate
					colour_map { 
						[0.00 rgb 0]
						[1.00 rgb 1]
					
					}
				}

}


difference {
isosurface {
    function { f_sphere(x, y, z, 2) + fn_Pigm(x/2, y, z/2).gray*0.25}
    accuracy 0.01
    max_gradient 3.579
    contained_by { box { -3, 3 } }
		texture { 
		slope y
		//turbulence 0.08
		texture_map{ 
			[1 
				pigment {
					gradient y
					turbulence 0.5
					octaves 1 
					frequency 4 triangle_wave
					colour_map { 
						[0.00 rgb 0.25]
						[0.03 rgb <1,.7,.6>*0.75]
						[0.40 rgb <1,.7,.6>*0.75]
						[0.40 rgb <1,.4,.8>*0.75]
						[0.42 rgb <1,.7,.6>*0.75]
						[1.00 rgb <1,.7,.6>*0.25]
					}
					scale <1,0.1,1>
					//rotate <23,0,30>
				}
				finish { ambient 0 diffuse 0.7 brilliance 10 specular 0.4 roughness 1 metallic reflection 0.2 }
				normal { 
					average 
					normal_map { 
						[1 bozo 0.6 octaves 1 frequency 4 scallop_wave scale <1,0.1,1>]
						[0.3 granite 0.2 scale 0.1] 
					} 
				} 
				
			]
			[1 
				pigment { colour rgb 1 }
				finish { ambient .8 diffuse 1 brilliance 0.1 specular 0.5 roughness 0.001 reflection 0.3 }
				normal { wrinkles 0.1 scale 0.00001}
			]
		}
	}

	scale y*1.8
	rotate y*45
	no_shadow
}
text {
  ttf             // font type (only TrueType format for now)
  "crystal.ttf",  // Microsoft Windows-format TrueType font file name
  "?",      // the string to create
  0.5,              // the extrusion depth
  0               // inter-character spacing
pigment{
	gradient y
	color_map {
		[0 color White]
		[0.5 color Red ]
		}
	}
finish { reflection 0.5 }
scale 5
translate <-1,-0.5,-2>
}

}

sphere {0,1
	pigment {rgbt 1 }
	hollow
    interior              // ...à l'intèrieur.
    {
      media
      {
        intervals 5       // 5 échantillonnage de la lumière à l'intérieur de media
        samples 1, 10     // chantillonnage min, chantillonnage max 
        emission rgb 0.5  // ajoute de la lumière à la scène
        scale 1
        density           // c'est la qu'on va répartir les couleurs dans le media
        {
          spherical       // repartition sphèrique
          scale 0.62
          turbulence 0.5  // je vais vous secouer tous ca !!
          density_map     // on va utiliser des motifs avec nos couleurs pour simuler des flammes 
          {
            [ 0.0 color rgb 0 ]   // centre de media : blanc (chaud)
            [ 0.05 bozo color_map { [0 color rgb <0, 0.3, 0.5> ] [1 Black ] } scale 0.15 ]   // extèrieur du media : motif "bozo" pour faire des flammes de couleurs bleu foncé
            [ 0.1 bozo color_map { [0 color rgb <0, 0.5, 1> ] [1 Black ] } scale 0.15 ]    // intèrieur du media : motif "bozo" pour faire des flammes de couleurs bleu claire
            [ 1.0 color rgb 1 ]   // centre de media : blanc (chaud)
          }     
        }
      }
    }


	scale <5, 3, 3>*1.5
	translate y*-3
	
 
}

// Create an infinite sphere around scene and allow any pigment on it
sky_sphere {
  pigment {
    gradient y
    color_map {
    	[0.0 color rgb <0.7,0.7,1.0>*0.5]
    	[0.5 color blue 0.2]
    }
  }
rotate x*15
}



sphere {0, 2000

texture {
    pigment {
        granite
        color_map {
            [ 0.000  0.270 color Clear color Clear ]
            [ 0.270  0.280 color rgb <.5,.5,.4> color rgb <.8,.8,.4> ]
            [ 0.280  0.470 color Clear color Clear ]
            [ 0.470  0.480 color rgb <.4,.4,.5> color rgb <.4,.4,.8> ]
            [ 0.480  0.680 color Clear color Clear ]
            [ 0.680  0.690 color rgb <.5,.4,.4> color rgb <.8,.4,.4> ]
            [ 0.690  0.880 color Clear color Clear ]
            [ 0.880  0.890 color rgb <.5,.5,.5> color rgb < 1, 1, 1> ]
            [ 0.890  1.000 color Clear color Clear ]
        }
    turbulence 1
    sine_wave
    scale .5
    }
    finish { diffuse 0 ambient 1 }
}


	hollow
}



sphere {0, 1000
	pigment {
		bozo
		turbulence 0.75
		//octaves 1
		//frequency 4
		color_map {
			[0.0 , 0.3 color White color rgb <0.6,0.6,1.0>]
			[0.3 , 0.5 color rgb <0.6, 0.6, 1.0> color Clear]
			}
		scale <10, 5, 10>*25
		//rotate z*15
		}
	hollow
}