#include "colors.inc"
#include "functions.inc"
#include "outline.inc"

global_settings
{
  ambient_light 1
}

#declare CamLoc = <0,3,-4>;
#declare CamLookAt = <0,0.5,0>;
#declare CamAngle = 48;

camera
{
  location CamLoc
  look_at CamLookAt
  angle CamAngle
}

background
{
  color White
}

#declare NX = 15;
#declare NZ = NX;

#declare VertexCount = NX*NZ;
#declare FaceCount = 2*(NX-1)*(NZ-1);

#declare XMin = -1;
#declare XMax = 1;
#declare ZMin = -1;
#declare ZMax = 1;

#declare Vertices = array[VertexCount]

#declare J = 0;
#while (J < NZ)
  #declare I = 0;
  #while (I < NX)
    #declare X = XMin+I/(NX-1)*(XMax-XMin);
    #declare Z = ZMax-J/(NZ-1)*(ZMax-ZMin);
    #declare Vertices[J*NX+I] = <X,f_wrinkles(X,0,Z),Z>;
    #declare I = I + 1;
  #end
  #declare J = J + 1;
#end

#declare Faces = array[FaceCount]

#declare J = 0;
#while (J < NZ-1)
  #declare I = 0;
  #while (I < NX-1)
    #declare Faces[2*(J*(NX-1)+I)]   = <J*NX+I,(J+1)*NX+I,J*NX+I+1>;
    #declare Faces[2*(J*(NX-1)+I)+1] = <(J+1)*NX+I,(J+1)*NX+I+1,J*NX+I+1>;
    #declare I = I + 1;
  #end
  #declare J = J + 1;
#end

object
{
  Outline_Mesh(Vertices, Faces, CamLoc, CamLookAt, CamAngle, 1)
  pigment {color Black}
  finish {diffuse 0 ambient 1}
}

mesh2
{
  vertex_vectors
  {
    VertexCount
    #declare I = 0;
    #while (I < VertexCount)
      Vertices[I]
      #declare I = I + 1;
    #end
  }
  face_indices
  {
    FaceCount
    #declare I = 0;
    #while (I < FaceCount)
      Faces[I]
      #declare I = I + 1;
    #end
  }
  pigment {color Green}
  finish {diffuse 0 ambient 1}
}