// shiny_metal.pov
// 2004 Samuel Benge
// For best results, render with +a0.01 +r4

global_settings{
 assumed_gamma 1
}

#default{finish{ambient 0 }}

camera{ 
 fisheye 
 right x*.7 up y*.7  
 location <15,20,-40>*1.9
 look_at 0
 angle 30 
}

light_source{
 <50,100,-75>,<1 1 .8>*4
 fade_power 2
 fade_distance 89
 area_light x*50,z*50,3,3
 jitter
 adaptive 1
 orient
 circular
}

#declare shape=
union{
 // Intersected Height Field
 intersection{
  height_field{
   function 800,800{
    pigment{
     average    
     pigment_map{      
      #local V=0;
      #while(V<180)
       [1
        pigment_pattern{
         planar        
         rotate z*V 
         scale .4
         translate<.5,.5,0>
         triangle_wave
         frequency 1
        }
        poly_wave .5        
       ]       
       #local V=V+180/5;
      #end      
     }    
    }
   }  
   smooth
   translate<-.5,0,-.5>
   scale<20,5,20> rotate x*270  
  } 
  box{<-9.9,-9.9,-10>,<9.9,9.9,10>}
  pigment{rgb .5}
  finish{
   diffuse .5
   brilliance 4
   reflection .5
   phong 2
   phong_size 200
   specular .3
   roughness .05
  }
  normal{
   granite .07
   scale .01
   accuracy .1
  }
  rotate y*15
 }
 // Room
 box{<-15,-10,-100>,<100,150,15>} 
 cylinder{<-15,-10,15>,<-15,150,15>,.5}
 cylinder{<-15,-10,15>,<-15,-10,-100>,.5}
 cylinder{<-15,-10,15>,<100,-10,15>,.5}
}

object{shape
 pigment{rgb .5}
 finish{
  diffuse .25
  brilliance 4
  reflection .75
  phong 2
  phong_size 200
  specular .3
  roughness .05
 }
 normal{
  average
  normal_map{
   [1 granite .07 scale .01 accuracy .1]
   [1 quilted scale 2]
  }
 } 
}